Métodos abreviados de teclado en una versión no inglesa de Microsoft Office

Tengo un gran problema con la versión portuguesa de MS Office 2007 y 2010.

Se cambian los accesos directos estándar que utiliza cualquier aplicación común.
Algunos atajos que no funcionan: Ctrl+ s(guardar), Ctrl+ f(buscar) y Ctrl+ a(seleccionar todo).

Quiero configurarlo para usar los accesos directos de la versión en inglés.

Hay una opción que permite configurar cada acceso directo por separado. Además, tengo que configurar para cada aplicación, si configuro en Word, tendré que configurar nuevamente para Excel.

¿Cómo usar los accesos directos de la versión en inglés de MS Office independientemente del idioma de Office?

Gracias

Estoy casi seguro de que no hay una forma integrada de cambiar los accesos directos en las aplicaciones de MS Office.

Sin embargo, puede usar AutoHotkey para este propósito.

La secuencia de comandos

^a::
^f::
^s::
    WinGet, Process, ProcessName, A
    if(RegExMatch(Process, "^(WINWORD|EXCEL)\.EXE$"))
    {
       if(A_ThisHotKey = "^a")
           SendPlay, ^e
       if(A_ThisHotKey = "^f")
           SendPlay, ^b
       if(A_ThisHotKey = "^s")
           SendPlay, ^g
    }
    else
        SendPlay, %A_ThisHotKey%
return

Cómo funciona

• ^a::, especifica una de las teclas de acceso rápido que ejecuta el script antes de la returninstrucción, donde ^indica la Ctrlclave.

• WinGet, Process, ProcessName, Aalmacena el Anombre del proceso de la ventana active ( ) en la variable Process.

• if(RegExMatch(Process, "^(WINWORD|EXCEL)\.EXE$")) {...} else ...comprueba si Process coincide con la expresión regular , es decir, si coincide con una de las cadenas WINWORD.EXEo EXCEL.EXE.

  • Si es así, se ejecuta el primer bloque.

    • if(A_ThisHotKey = "^a")comprueba si la tecla de acceso rápido presionada es Ctrl+ A.

      Si es así, simula la tecla de bombardeo Ctrl+ E, que es la tecla de acceso rápido portuguesa para seleccionar todos los ¹ .

  • De lo contrario, SendPlay, %A_ThisHotKey%simula la combinación de teclas que se presionó inicialmente.

    De esta manera, otras aplicaciones aún se comportan como deberían.

Cómo utilizar

1. Descargue e instale la última versión de AutoHotkey.

2. Guarde el script anterior como ms-office.ahk, utilizando su editor de texto favorito.

3. Haga doble clic en el archivo para ejecutar el script.

4. Si lo desea, copie el script (o un enlace a él) en la Startupcarpeta.

5. Para agregar más aplicaciones de MS Office, simplemente modifique la expresión regular.

   Para agregar PowerPoint, por ejemplo, reemplazar (WINWORD|EXCEL)por (WINWORD|EXCEL|POWERPNT).

6. Para agregar más teclas de acceso rápido, debe modificar dos partes del script.

   Para agregar Ctrl+ O(Abrir ...), por ejemplo, agregue la línea ^o::a la lista en la parte superior agregue estas líneas dentro del ifbloque:

   if(A_ThisHotKey = "^o")
       SendPlay, ^a
   

¹ Al menos, creo que lo es. Tomé las teclas rápidas de mi MS Office en español. Ajuste si es necesario.

Según la respuesta anterior, un par de atajos más (se podrían agregar a la respuesta anterior):

^a::
^f::
^s::
^w::
^n::
^u::
^d::
^r::
^b::
^i::
^k::
^g::
    WinGet, Process, ProcessName, A
    if(RegExMatch(Process, "^(EXCEL)\.EXE$"))
    {
       if(A_ThisHotKey = "^a") ;seleccionar rango
           SendPlay, ^e
       if(A_ThisHotKey = "^f") ;buscar
           SendPlay, ^b
       if(A_ThisHotKey = "^s") ;guardar
           SendPlay, ^g
       if(A_ThisHotKey = "^w") ;cerrar
           SendPlay, ^r
       if(A_ThisHotKey = "^n") ;nuevo libro
           SendPlay, ^u
       if(A_ThisHotKey = "^u") ;subrayar
           SendPlay, ^s
       if(A_ThisHotKey = "^b") ;negrita
           SendPlay, ^n
       if(A_ThisHotKey = "^i") ;cursiva
           SendPlay, ^k
       if(A_ThisHotKey = "^d") ;filldown
           SendPlay, ^j
       if(A_ThisHotKey = "^r") ;fill right
           SendPlay, ^d
       if(A_ThisHotKey = "^k") ;hyperlink
           SendPlay, ^!k
       if(A_ThisHotKey = "^g") ;goto
           SendPlay, ^i
    }
    else
        SendPlay, %A_ThisHotKey%
return