¿Cómo uso derivados del espacio de pantalla para antialias de una forma paramétrica en un sombreador de píxeles?

En el documento Valve's Alpha Tested Magnification , menciona el uso de "derivados de espacio de pantalla por píxel" para hacer suavizado. Mi opinión es que este es el ddxe ddyintrínsecas funciones en HLSL?

Estoy tratando de dibujar formas paramétricas (por ejemplo, un círculo: x² + y² <1 ) en un sombreador, y no sé cómo usar esta técnica para suavizar correctamente los píxeles del borde de mi forma. ¿Alguien puede dar un ejemplo?

Para completar, aquí hay un ejemplo del tipo de sombreador de píxeles que estoy haciendo:

float4 PixelShaderFunction(VertexShaderOutput input) : COLOR0
{
    float dist = input.TexCoord.x * input.TexCoord.x
               + input.TexCoord.y * input.TexCoord.y;
    if(dist < 1)
        return float4(0, 0, 0, 1);
    else
        return float4(1, 1, 1, 1);
}

Tomando su ejemplo, tiene una función de paso de la distancia, que produce un borde perfectamente duro (alias). Una forma simple de antialias del círculo sería convertirlo en un umbral blando, como:

float distFromEdge = 1.0 - dist;  // positive when inside the circle
float thresholdWidth = 0.01;  // a constant you'd tune to get the right level of softness
float antialiasedCircle = saturate((distFromEdge / thresholdWidth) + 0.5);
return lerp(outsideColor, insideColor, antialiasedCircle);

Aquí utilicé una rampa lineal sujeta para una función de umbral suave, pero también podría usar smoothstepo algo más. El + 0.5es centrar la rampa en la ubicación matemática del borde. De todos modos, el punto es que esta función cambia suavemente desde outsideColorque insideColormás de algún rango de distancias, por lo que si tienes que elegir thresholdWidthadecuadamente obtendrá una ventaja mirando antialiased.

¿Pero cómo debes elegir thresholdWidth? Si es demasiado pequeño, volverá a aparecer el alias, y si es demasiado grande, el borde estará demasiado borroso. Además, generalmente dependerá de la posición de la cámara: si distse mide en unidades de espacio mundial o espacio de textura, entonces una thresholdWidthque funcione para una posición de cámara será incorrecta para otra.

Aquí es donde entran las derivadas del espacio de pantalla (sí, son las funciones ddxy ddycomo lo adivinó). Al calcular la longitud del gradiente dist, puede hacerse una idea de qué tan rápido está cambiando en el espacio de la pantalla y usarlo para estimar thresholdWidth, por ejemplo:

float derivX = ddx(distFromEdge);
float derivY = ddy(distFromEdge);
float gradientLength = length(float2(derivX, derivY));
float thresholdWidth = 2.0 * gradientLength;  // the 2.0 is a constant you can tune

Aún tiene un valor que puede ajustar para obtener el nivel deseado de suavidad, pero ahora debería obtener resultados consistentes independientemente de la posición de la cámara.