Una fórmula de hoja de cálculo para asignar calificaciones de letras basadas en rangos numéricos

8

Estoy tratando de descubrir cómo escribir una declaración IF que será 'verdadera' si un valor está entre dos valores.

Ejemplo:

Si el valor está entre 60 y 69.9, devuelva "D"

Si el valor está entre 70 y 79.9, devuelva "C"

Si el valor está entre 80 y 89,9, devuelve "B"

Tengo esto, pero no puedo entender cómo modificarlo, por lo que la prueba es intermedia en lugar de menor o mayor que.

=IF(A1<60, "F", IF(A1>60, "A", 0))

google-sheets formulas worksheet-function

— Señor b
fuente

8

Mantenga los signos de desigualdad en la misma dirección:

=IF(A1<60, "F", IF(A1<70, "D", IF(A1<80, "C", IF(A1<90, "B", "A"))))

Lo anterior funciona bien siempre que no haya demasiados casos. Pero si tuviera muchas opciones, C-, C +, B-, B + ... sería mejor usar una tabla de búsqueda. Por ejemplo, si tiene una tabla de búsqueda como la siguiente, entonces

=vlookup(A1, $K$1:$L$5)

realiza el mismo trabajo que los IF anidados. La tabla también es más fácil de mantener en caso de cambios: por ejemplo, decidió mover algunos límites.

+---+----+---+
|   | K  | L |
+---+----+---+
| 1 |  0 | F |
| 2 | 60 | D |
| 3 | 70 | C |
| 4 | 80 | B |
| 5 | 90 | A |
+---+----+---+

¿No es necesario un tercer argumento para buscar en Google Docs?

— Ellen Spertus

3

Otra solución, tomada del Foro de ayuda de Google Docs , mantiene los puntos de corte directamente en la fórmula, eliminando así el mantenimiento por separado.

Para los límites definidos en OP, la fórmula es

=VLOOKUP($A1,{0,"F";60,"D";70,"C";80,"B";90,"A"},2)

Cambiar los límites puede parecer engorroso ahora, pero se puede hacer de manera eficiente de la siguiente manera. Cambie los límites en la fórmula en la celda superior y luego fill downhaciendo una CMD-Do CTRL-Ddependiendo de su plataforma.

— wsaleem
fuente

3

Modifiqué los límites de @ wsaleem para incluir - / + calificaciones (según la escala de mi universidad):

=VLOOKUP(BB2,{0,"F";60,"D-";63,"D";68,"D+";70,"C-";73,"C";78,"C+";80,"B-";83,"B";88,"B+";90,"A-";93,"A"},2)

Asegúrese de REDONDEAR () su valor de entrada. Estaba usando PROMEDIO () y aunque el campo se redondeó visiblemente, el valor no lo era.

— ow3n
fuente

Estoy tratando de convertir una calificación de letra a un número de GPA. Intenté el siguiente BUSCADOR, cuando la calificación de la letra está en la columna O: = vlookup ($ O2, {F, "0"; D, "1.0"; C -, "1.67"; C, "2.0"; C +, " 2.33 "; B -," 2.67 "; B," 3.0 "; B +," 3.33 "; A -," 3.67 "; A," 4.0 "} 2) Realmente no sé lo que estoy haciendo. ¿Para qué es el último "2" después del paréntesis final, pero antes de los paréntesis finales?

— user205307

Le falta una coma entre el rango y el 2 (estos son parámetros separados por comas). Consulte la documentación support.google.com/docs/answer/3093318?hl=es

— ow3n