Estoy intentando cambiar el valor de una celda en Hojas de cálculo de Google en función del valor de una celda adyacente. Esta celda adyacente obtiene su valor del color de la celda adyacente usando la fórmula de esta respuesta de Quora. Por lo tanto, el valor de la celda debe cambiar según el código hexadecimal que se obtiene del color de la primera celda. Hay cuatro posibles valores hexadecimales en este momento, por lo que estaba tratando de poner cuatro declaraciones IF diferentes en la misma celda, por lo que su valor cambia en función de esto.

Mi primer intento condujo a un error de análisis de fórmula:

=if((J2="#00ff00","Read"), if(j2="#ff0000", "Unread"), if(j2="#ff9900","In Progress"), if(j2="#000000", "Not Applicable"))

Está claro que no puede simplemente separarse si las declaraciones con comas. En base a esta pregunta de desbordamiento de pila, probé este código, con instrucciones IF anidadas:

=if((J2="#00ff00","Read", if(j2="#ff0000", "Unread", if(j2="#ff9900","In Progress",if(j2="#000000", "Not Applicable")))))

Esto también conduce a un error de análisis de fórmula.

¿Hay alguna manera de que simplemente pueda incluir múltiples declaraciones IF en la misma celda que funcionarán para mi código?

Usar en lookuplugar de if:

=lookup(B7,
       {"#000000","#00ff00","#ff0000","#ff9900"},
       {"Not applicable", "Read","Unread","In Progress"}
  ) 

Tenga en cuenta que el segundo parámetro debe ser una lista ordenada.

Respuesta corta

El problema en los ejemplos proporcionados son los paréntesis. Aplicarlos adecuadamente.

Explicación

IF() La función debe tener dos parámetros y, opcionalmente, un tercero.

IF(logical_expression, value_if_true, value_if_false)

El problema específico con

• El primer ejemplo proporcionado es que el exterior IF()tiene demasiados parámetros.
• el segundo ejemplo es que el logical_expressiondel exterior IF()no regresa TRUEoFALSE

En las Hojas de cálculo de Google, los parámetros de las funciones están separados por comas (o punto y coma si su hoja de cálculo usa una coma como separador decimal). Cuando se usan paréntesis para encerrar varias operaciones y funciones dentro de una función, se consideran como un parámetro de la función que las contiene.

Una práctica común es poner lo interno IF()como el value_if_false, pero podría hacerse de muchas maneras. Agregar IF()dentro de otro otro como value_if_truey value_if_falsese llama IF() logical test nestingo simplemente IF() nesting.

A continuación se muestra un ejemplo de una fórmula que tiene tres IF(), dos de ellas utilizadas para determinar la value_if_falsedel padre IF(). Se aplica una alineación vertical y de varias líneas del estilo de paréntesis para facilitar la lectura.

 =IF(logical_expression, value_if_true, 
     IF(logical_expression, value_if_true, 
        IF(logical_expression, value_if_true, value_if_false
          )
       )
    )

El estilo anterior podría usarse en la escritura de fórmulas de Hojas de cálculo de Google. Lo encontré útil para la depuración de fórmulas.

Referencia

• IF - Ayuda de editores de Google Docs

Acabo de descubrir cómo combinar si y o.

Ejemplo:

=IF(OR(B3>49,C3>49,D3>49),”Passed”,”Failed”)
=IF(AND(B3>49,C3>49,D3>49),”Passed”,”Failed”)
=IF(OR(AND(B3>49,C3>49),AND(B3>49,D3>49),AND(C3>49,D3>49)),”Won”,”Failed”)

Entonces, para su ejemplo:

= if(OR(J2="#00ff00",j2="#ff0000",j2="#ff9900"),"True","False")

Fuente: Uso combinado de las funciones lógicas IF, AND, OR en la hoja de cálculo de Google Doc .

Puede anidar sentencias IF por ejemplo

If(if(if(when all 3 equal true)))

Trabajaría

O

podría usar un IFAND anidado, por ejemplo

IF(AND(AND()))

También funcionaría

Le han ofrecido teoría y mejores enfoques, pero para responder específicamente:

¿Hay alguna manera de que simplemente pueda incluir múltiples declaraciones IF en la misma celda que funcionarán para mi código?

por favor, inténtalo:

=if(J2="#00ff00","Read", if(J2="#ff0000", "Unread", if(J2="#ff9900","In Progress",if(J2="#000000", "Not Applicable"))))

Es decir, su segundo intento sin el primer paréntesis de apertura y sin el último paréntesis de cierre.