¿Cómo elimino el '0' de un campo con una ecuación?

11

Tengo una hoja de cálculo de Google que ingreso en nuevos valores todos los días y quiero que la ecuación se ejecute en toda la columna para no tener que arrastrar el cuadro del día anterior hacia abajo para copiar la información.

Funcionaría bien arrastrar el cuadro hasta el final de la hoja, pero luego las celdas se llenan con a 0.

¿Cómo puedo poner la ecuación en las celdas sin que me den un valor de inmediato? es decir, solo haga que muestren un valor cuando el resto de esa fila contenga información.

google-sheets

— v15
fuente

15

Del menú:

Formato> Número> Más formatos> Formato de número personalizado
Escribir #,##0_);"("#,##0")";"-"_)

— David Choi
fuente

2

El mínimo: #;-#;produce el número sin cambios si es positivo, el número sin cambios si es negativo (pero con un guión como prefijo) y una cadena vacía si está en blanco.

— Nick May

Sin embargo, esto no ayudará si está intentando que esas celdas no aparezcan en un gráfico; use un if / ifblank como se describe en otra parte.

— Nick May

2

¡Frio! Ejemplo con 2 decimales:#,##0.00_);(#,##0.00);"-"_)

— tokland el

6

Envolvería su fórmula en una declaración if que da como resultado "" si la fila está en blanco. Entonces puedes copiar todo el camino hacia abajo. Me gusta esto:

=if(A1="","",your_formula_here)

Me han dicho que este es el camino a seguir si desea excluir los resultados cero y no solo ocultarlos, si estaba tomando un promedio o algo así.

— Trass Vasston

3

No necesita completar una fórmula en toda la columna. Utilice la fórmula de matriz en su lugar y elimine la necesidad de arrastrar por la hoja

Por ejemplo, si desea celdas de la columna D contienen el producto de las células de B y C, y la columna E contiene suma de B y C, en lugar de poner D1 = B1*C1y E1 = B1 + C1y arrastre hacia abajo pones esto en D1 y E1, respectivamente

=ARRAYFORMULA(B:B*C:C)
=ARRAYFORMULA(B:B + C:C)

Luego, la fórmula se aplicará automáticamente a toda la columna sin arrastrar nada. X:Xse refiere a la columna X. Si desea incluir solo desde la fila 3 hasta el uso finalX3:X

Eso aplicará la fórmula a toda la columna y, por lo tanto, mostrará ceros en las filas que no tienen datos. Entonces, para no mostrar nada en las filas vacías , es decir, calcular solo las filas que tienen datos en la columna B (excepto la fila del encabezado) y ocultar los 0 a continuación como desee, use esto

=ARRAYFORMULA(IF(B2:B<>0, B2:B + C2:C, ""))

En aplicaciones fuera de línea como MS Office y LibreOffice para usar la fórmula de matriz, deberá presionar Ctrl+ Shift+ en Enterlugar de la ARRAYFORMULAfunción

Si desea ocultar 0s dentro de la tabla , puede usar un formato condicional

Seleccione las celdas que desea eliminar 0s
Seleccione el menú Formato > Formato condicional > agregue la condición "es igual a" e ingrese 0 en el cuadro de texto
En el estilo de formato, cambie el color del texto a blanco o ninguno
Presione Listo

Ahora cada celda que sea igual a 0 estará en blanco

— phuclv
fuente

2

Aquí hay una referencia útil:

Revise las pautas para personalizar un formato de número

Es un enlace a las pautas de support.office.com para el formato de números de Excel, desglosadas en secciones sobre cómo incluir texto, decimales, espacios, colores, tipos de moneda, formatos de fecha y hora, etc.

— Amy W
fuente

1

Si su resultado depende de más de una celda, puede evitar que aparezca cualquier cosa hasta que se completen todas las celdas de referencia necesarias:

=IF(OR(ISBLANK(A1),ISBLANK(B1),ISBLANK(C1)),,your_formula_here(A1,B1,C1))

Si tiene algunas celdas opcionales (por ejemplo, C1aquí), use AND():

=IF(AND(OR(ISBLANK(A1),ISBLANK(B1)),ISBLANK(C1)),,your_formula_here(A1,B1,C1))

— Chris
fuente