Un mejor comando de pegar

Tengo los siguientes dos archivos (rellené las líneas con puntos para que cada línea de un archivo tenga el mismo ancho y puse file1 todo en mayúsculas para que quede más claro).

contents of file1:

ETIAM......
SED........
MAECENAS...
DONEC......
SUSPENDISSE

contents of file2

Lorem....
Proin....
Nunc.....
Quisque..
Aenean...
Nam......
Vivamus..
Curabitur
Nullam...

Observe que file2 es más largo que file1.

Cuando ejecuto este comando:

paste file1 file2

Me sale esta salida

ETIAM...... Lorem....
SED........ Proin....
MAECENAS... Nunc.....
DONEC...... Quisque..
SUSPENDISSE Aenean...
    Nam......
    Vivamus..
    Curabitur
    Nullam...

¿Qué puedo hacer para que la salida sea la siguiente?

ETIAM...... Lorem....
SED........ Proin....
MAECENAS... Nunc.....
DONEC...... Quisque..
SUSPENDISSE Aenean...
            Nam......
            Vivamus..
            Curabitur
            Nullam...

Lo intenté

paste file1 file2 | column -t

pero hace esto:

ETIAM......  Lorem....
SED........  Proin....
MAECENAS...  Nunc.....
DONEC......  Quisque..
SUSPENDISSE  Aenean...
Nam......
Vivamus..
Curabitur
Nullam...

no tan feo como el resultado original pero de todos modos incorrecto en columnas.

Suponiendo que no tiene caracteres de tabulación en sus archivos,

paste file1 file2 | expand -t 13

con el argumento -telegido adecuadamente para cubrir el ancho de línea máximo deseado en el archivo1.

OP ha agregado una solución más flexible:

Hice esto para que funcione sin el número mágico 13:

paste file1 file2 | expand -t $(( $(wc -L <file1) + 2 ))

No es fácil de escribir, pero se puede usar en un script.

Pensé que awk podría hacerlo bien, así que busqué en Google "awk leyendo la entrada de dos archivos" y encontré un artículo sobre stackoverflow para usar como punto de partida.

Primero está la versión condensada, luego comentamos completamente debajo. Esto tardó más de unos minutos en resolverse. Me alegraría algunos refinamientos de personas más inteligentes.

awk '{if(length($0)>max)max=length($0)}
FNR==NR{s1[FNR]=$0;next}{s2[FNR]=$0}
END { format = "%-" max "s\t%-" max "s\n";
  numlines=(NR-FNR)>FNR?NR-FNR:FNR;
  for (i=1; i<=numlines; i++) { printf format, s1[i]?s1[i]:"", s2[i]?s2[i]:"" }
}' file1 file2

Y aquí está la versión completamente documentada de lo anterior.

# 2013-11-05 mike@diehn.net
# Invoke thus:
#   awk -f this_file file1 file2
# The result is what you asked for and the columns will be
# determined by input file order.
#----------------------------------------------------------
# No matter which file we're reading,
# keep track of max line length for use
# in the printf format.
#
{ if ( length($0) > max ) max=length($0) }

# FNR is record number in current file
# NR is record number over all
# while they are equal, we're reading the first file
#   and we load the strings into array "s1"
#   and then go to the "next" line in the file we're reading.
FNR==NR { s1[FNR]=$0; next }

# and when they aren't, we're reading the
#   second file and we put the strings into
#   array s2
{s2[FNR]=$0}

# At the end, after all lines from both files have
# been read,
END {
  # use the max line length to create a printf format
  # the right widths
  format = "%-" max "s\t%-" max "s\n"
  # and figure the number of array elements we need
  # to cycle through in a for loop.
  numlines=(NR-FNR)>FNR?NR-FNR:FNR;
  for (i=1; i<=numlines; i++) {
     printf format, s1[i]?s1[i]:"", s2[i]?s2[i]:""
  }
}

No es una muy buena solución, pero pude hacerlo usando

paste file1 file2 | sed 's/^TAB/&&/'

donde TAB se reemplaza con el carácter de tabulación.

En Debian y derivados, columntiene una opción de -n nomerge que permite a la columna hacer lo correcto con campos vacíos. Internamente, columnutiliza la wcstok(wcs, delim, ptr)función, que divide una cadena de caracteres anchos en tokens delimitados por los caracteres anchos en el delimargumento.

wcstokcomienza saltando caracteres anchos delimantes de reconocer el token. La -nopción utiliza un algoritmo que no omite los caracteres anchos iniciales delim.

Desafortunadamente, esto no es muy portátil: -nes específico de Debian, y columnno está en POSIX, aparentemente es algo BSD.

Sacando los puntos que usaste para el relleno:

archivo1:

ETIAM
SED
MAECENAS
DONEC
SUSPENDISSE

file2:

Lorem
Proin
Nunc
Quisque
Aenean
Nam
Vivamus
Curabitur
Nullam

Prueba esto:

$ ( echo ".TS"; echo "l l."; paste file1 file2; echo ".TE" ) | tbl | nroff | more

Y obtendrás:

ETIAM         Lorem
SED           Proin
MAECENAS      Nunc
DONEC         Quisque
SUSPENDISSE   Aenean
              Nam
              Vivamus
              Curabitur
              Nullam

Una awksolución que debería ser bastante portátil y debería funcionar para un número arbitrario de archivos de entrada:

# Invoke thus:
#   awk -F\\t -f this_file file1 file2

# every time we read a new file, FNR goes to 1

FNR==1 {
    curfile++                       # current file
}

# read all files and save all the info we'll need
{
    column[curfile,FNR]=$0          # save current line
    nlines[curfile]++               # number of lines in current file
    if (length > len[curfile])
            len[curfile] = length   # max line length in current file
}

# finally, show the lines from all files side by side, as a table
END {
    # iterate through lines until there are no more lines in any file
    for (line = 1; !end; line++) {
            $0 = _
            end = 1

            # iterate through all files, we cannot use
            #   for (file in nlines) because arrays are unordered
            for (file=1; file <= curfile; file++) {
                    # columnate corresponding line from each file
                    $0 = $0 sprintf("%*s" FS, len[file], column[file,line])
                    # at least some file had a corresponding line
                    if (nlines[file] >= line)
                            end = 0
            }

            # don't print a trailing empty line
            if (!end)
                    print
    }
}