¿Cómo verifica si existe un archivo dentro de awk? [-d 'nombre de archivo'] falla

Estoy tratando de generar una lista de usuarios que tienen un conjunto de directorios de inicio que no existe. Parece que debería poder hacer esto con awk, pero algo está mal con mi sintaxis.

Sigue diciéndome "Sintaxis inválida" en el]. ¿Qué estoy haciendo mal?

awk -F: '{ if(![ -d "$6"]){ print $1 " " $3 " " $7}}' /etc/passwd

El código final que probablemente terminaré usando es:

awk -F: '{if(system( "[ -d " $6 " ]") == 1 && $7 != "/sbin/nologin" ) {print "The directory " $6 " does not exist for user " $1 }}' /etc/passwd

Y tengo una pregunta relacionada aquí .

Podrías usar

system (comando) 
    Ejecute el comando de comando del sistema operativo y luego
    regrese al programa awk. Estado de salida del comando de retorno . 

p.ej:

awk -F: '{if(system("[ ! -d " $6 " ]") == 0) {print $1 " " $3 " " $7}}' /etc/passwd

No creo que [ -d ]sea ​​una awkcosa, eso es una cáscara. En cambio, lo haría de esta manera:

awk -F: '{ print $1,$3,$7}' /etc/passwd | 
    while read name uid shell; do 
        [ -d "/home/$name" ] || echo "$name $uid $shell"; 
    done

Por supuesto, como señaló muy correctamente @Janis, puede hacer todo en el shell:

while IFS=: read  name x uid x x x shell rest; do
     [ -d "/home/$name" ] || echo "$name $uid $shell" 
done < /etc/passwd

Puedes usar getline :

awk 'BEGIN {print getline < "file" < 0 ? "not exists" : "exists"}'

Si realmente está utilizando gawk(aunque puede estar utilizando nawk, o mawk, en cuyo caso esto no se aplica), puede hacerlo de forma nativa utilizando una de las extensiones cargables disponibles desde v4.0. Estoy usando gawk-4.1.x(v4.0 tenía una variación en la sintaxis para cargar extensiones).

Al cargar la filefuncsextensión se agrega (entre otras) una stat()función:

@load "filefuncs"
BEGIN {FS=":"}
(NF==7) {
   printf("user: %s %i %i\n",$1,$3,$4)
   rc=stat($6,fstat)
   err=ERRNO  # ERRNO is a string, not an int!
   if (rc<0) { 
       printf(" error: %s rc=%i %s\n",$6,rc,err)
   } else {
      if (fstat["type"]!="directory") 
        printf("  ENOTDIR: %s %s\n",$6,fstat["type"])
      if (fstat["uid"]!=$3) 
        printf("  uid mismatch: %s %i!=%i\n",$6,fstat["uid"],$3)
      if (fstat["gid"]!=$4) 
        printf("  gid mismatch: %s %i!=%i\n",$6,fstat["gid"],$4)
   }
}

Consulte la filefuncs(3am)página del manual para obtener detalles sobre esta extensión.

Corre con algo como:

gawk -f testhome.awk <(getent passwd)    # bash/zsh and glibc
gawk -f testhome.awk /etc/passwd

Puede confirmar que su gawkbinario admite extensiones con:

BEGIN { 
  if (!("api_major" in PROCINFO)) 
    printf("No extension API.\n")
  else
    printf("Extension API v%s.%s.\n",PROCINFO["api_major"],PROCINFO["api_minor"])
}

Aparte: gawktambién viene con una pequeña función de biblioteca para leer el passwdarchivo, puede invocarlo como:

gawk -i passwd.awk -- 'BEGIN { while(uu=getpwent()) {print uu;} endpwent(); }'

Prefiero usar getenten sistemas Linux / glibc ya que admite nsswitch.

Es casi awk ...

perl -F: -ane 'if(!-d $F[5]){ print "$F[0] $F[2] $F[6]" }' /etc/passwd

Aquí hay una solución que

• usos gawky/bin/sh
• ¿El directorio verifica con algún comando externo?
• pero lo hace de manera segura

Código:

gawk -F: '{
    cmd="IFS=\"\" read -r dir; [ -d \"$dir\" ]; echo $?";
    print $6 |& cmd;
    cmd |& getline x;
    close(cmd);
    if (x) print x " " $1 " " $3 " " $7
}' /etc/passwd

explicado:

• IFS="" read -r dir; [ -d "$dir" ]; echo $?es un código de shell que lee una ruta desde stdin y genera salidas 0si es un directorio, de lo contrario1
• print $6 |& cmdcanaliza el nombre del archivo al comando. |&es una extensión GNU-awk.
• cmd |& getline x lee la salida del comando en GNU-awk
• close(cmd) finaliza el comando, por lo que la siguiente línea puede ejecutar uno nuevamente
• if (x)ejecuta el printúnico if xis not 0(por lo que el directorio no existe)

Sin embargo, no recomiendo hacerlo de esta manera, porque es muy lento y torpe. Pero esta receta es segura , de modo que la entrada irregular no puede hacer daño. (Es poco probable que /etc/passwdcontenga datos dañinos, pero tal vez alguien quiera usarlo con datos de una fuente no confiable).

Si no puede usar gawk, esto es lamentable. En ese caso no tienes |&. Normal awksolo puede hacer uno de los siguientes tres:

• print "data" | cmd; close(cmd): Canalizar datos en un comando
• getline data < cmd; close(cmd): Leer datos de un comando
• ret = system(cmd): Obtener el código de retorno del comando

"Normal" awksimplemente no puede canalizar datos en un script y obtener algo de él nuevamente al mismo tiempo (al menos no encontré una manera de hacerlo), por lo que necesita un archivo intermedio (archivo temporal) que sea aún más torpe.

La observación interesante es que una tarea tan fácil se puede hacer solo con el shell:

dump_problems()
{
have=0;
while IFS=: read -r user pw id grp gcos dir shl;
do
  [ -d "$dir" ] && continue;
  echo "$user $id $shl";
  have=1;
done </etc/passwd;
return $have;
}

dump_problems && echo ALL OK >&2 || echo "Problems were found" >&2

No es necesario bash, cada Bourne-shell normal puede ejecutar el código anterior.

Tenga en cuenta que el código de shell anterior es un poco más elaborado de lo que realmente se necesita, pero esto será un indicador de cómo trabajar realmente con él (para personas que no tienen experiencia completa en cómo funciona shell).