Pase la variable de shell como a / patrón / a awk

Tener lo siguiente en una de mis funciones de shell:

function _process () {
  awk -v l="$line" '
  BEGIN {p=0}
  /'"$1"'/ {p=1}
  END{ if(p) print l >> "outfile.txt" }
  '
}

, así que cuando se llama como _process $arg, $argse pasa como $1y se usa como patrón de búsqueda. Funciona de esta manera, ¡porque la carcasa se expande $1en lugar del patrón awk! También lse puede usar dentro del programa awk, declarándose con -v l="$line". Todo muy bien.

¿Es posible de la misma manera dar un patrón para buscar como variable?

Seguir no funcionará,

awk -v l="$line" -v search="$pattern" '
  BEGIN {p=0}
  /search/ {p=1}
  END{ if(p) print l >> "outfile.txt" }
  '

, como awk no se interpretará /search/como una variable, sino literalmente.

Utilice el ~operador de awk , y no necesita proporcionar una expresión regular literal en el lado derecho:

function _process () {
    awk -v l="$line" -v pattern="$1" '
        $0 ~ pattern {p=1} 
        END {if(p) print l >> "outfile.txt"}
    '  
}

Aunque esto sería más eficiente (no tiene que leer todo el archivo)

function _process () {
    grep -q "$1" && echo "$line"
}

Dependiendo del patrón, puede querer grep -Eq "$1"

awk  -v pattern="$1" '$0 ~ pattern'

Tiene un problema que awkexpande las secuencias de escape ANSI C (como \npara nueva línea, \fpara alimentación de formulario, \\para barra diagonal inversa, etc.) en $1. Por lo tanto, se convierte en un problema si $1contiene caracteres de barra diagonal inversa que es común en las expresiones regulares (con GNU awk4.2 o superior, los valores que comienzan @/y terminan en /, también son un problema ). Otro enfoque que no sufre de ese problema es escribirlo:

PATTERN=$1 awk '$0 ~ ENVIRON["PATTERN"]'

Lo malo que será dependerá de la awkimplementación.

$ nawk -v 'a=\.' 'BEGIN {print a}'
.
$ mawk -v 'a=\.' 'BEGIN {print a}'
\.
$ gawk -v 'a=\.' 'BEGIN {print a}'
gawk: warning: escape sequence `\.' treated as plain `.'
.
$ gawk5.0.1 -v 'a=@/foo/' BEGIN {print a}'
foo

Sin awkembargo, todos funcionan igual para secuencias de escape válidas:

$ a='\\-\b' awk 'BEGIN {print ENVIRON["a"]}' | od -tc
0000000   \   \   -   \   b  \n
0000006

(contenido de $aaprobado tal cual)

$ awk -v a='\\-\b' 'BEGIN {print a}' | od -tc
0000000   \   -  \b  \n
0000004

( \\cambiado \y \bcambiado a un carácter de retroceso).

Intenta algo como:

awk -v l="$line" -v search="$pattern" 'BEGIN {p=0}; { if ( match( $0, search )) {p=1}}; END{ if(p) print l >> "outfile.txt" }'

No, pero puede simplemente interpolar el patrón en la cadena de comillas dobles que pasa a awk:

awk -v l="$line" "BEGIN {p=0}; /$pattern/ {p=1}; END{ if(p) print l >> \"outfile.txt\" }"

Tenga en cuenta que ahora tiene que escapar del literal awk entre comillas dobles, pero sigue siendo la forma más sencilla de lograr esto.

Puede usar la función eval que resuelve en este ejemplo la variable nets antes de ejecutar awk.

nets="searchtext"
eval "awk '/"${nets}"/'" file.txt