Método abreviado de teclado para cambiar entre hojas en Excel

¿Excel 2007 tiene un método abreviado de teclado que cambia entre hojas de trabajo?

Ctrl+ PgUppara moverse hacia la izquierda.

Ctrl+ PgDnpara moverse hacia la derecha.

Macros de VBA y método abreviado de teclado personalizado para activar la primera o la última hoja

Si desea que un atajo de teclado real salte a la primera o la última hoja de trabajo, coloque este código en un módulo en el libro de trabajo "PERSONAL":

Sub ToFirstSheet()
    Sheets(1).Activate
End Sub

Sub ToLastSheet()
    Sheets(Sheets.Count).Activate
End Sub

Vaya a la pestaña Desarrollador> Macros. Busque estas macros (ToFirstSheet y ToLastSheet). Seleccione uno, haga clic en Opciones y asigne un atajo de teclado. Haz lo mismo por el otro.

Al guardar esto en el libro "PERSONAL", estará disponible en cualquier archivo de Excel.

Atajos de teclado integrados para activar la hoja anterior o siguiente

Para saltar una hoja de trabajo hacia la izquierda o hacia la derecha, puede usar estos atajos de teclado predeterminados:

Ctrl+PgUp

Ctrl+PgDn

Macros de VBA para activar la hoja anterior o siguiente

Aquí le mostramos cómo lograr lo mismo usando VBA intente esto:

Sub ToPreviousSheet()
    If ActiveSheet.Index = 1 Then
        ActiveWorkbook.Worksheets(ActiveWorkbook.Worksheets.Count).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index - 1).Activate
    End If
End Sub

Sub ToNextSheet()
    If ActiveSheet.Index = ActiveWorkbook.Worksheets.Count Then
        ActiveWorkbook.Worksheets(1).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index + 1).Activate
    End If
End Sub

Funciones de VBA para devolver la hoja anterior o siguiente

Use esta función si prefiere obtener el objeto de hoja de trabajo anterior o siguiente:

Function GetPreviousSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = 1 Then
        Set GetPreviousSheet = targetBook.Worksheets(targetBook.Worksheets.Count)
    Else
        Set GetPreviousSheet = targetBook.Worksheets(targetSheet.Index - 1)
    End If
End Function

Function GetNextSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = targetBook.Worksheets.Count Then
        Set GetNextSheet = targetBook.Worksheets(1)
    Else
        Set GetNextSheet = targetBook.Worksheets(targetSheet.Index + 1)
    End If
End Function

Use las funciones de esta manera:

Sub EXAMPLE()
    MsgBox "Previous Sheet:  " & GetPreviousSheet(ActiveSheet).Name
    MsgBox "Next Sheet:  " & GetNextSheet(ActiveSheet).Name
    GetNextSheet(ActiveSheet).Activate
End Sub

También puede usar las teclas de aceleración para llegar al Gocuadro de diálogo. Luego puede escribir algo como foo!A1navegar a la celda superior izquierda en la hoja llamada "foo". Mientras que la página hacia arriba y hacia abajo son generalmente más rápidas. Si tiene una gran cantidad (por ejemplo, más de 20) de hojas bien nombradas, esto puede ser más rápido. Ir también funciona bien si ha nombrado tablas en sus hojas.

Al presionar F5 normalmente se abre el Gocuadro de diálogo.