¿Cómo sumar números de celdas alfanuméricas en Excel?

0

Estoy tratando de averiguar cómo agregar una lista de celdas que contengan valores alfanuméricos. Por ejemplo, si los datos de la celda son3.098 GB (3,326,698,574 bytes)

Estoy usando lo siguiente para quitar los corchetes y las letras:

=LEFT(G55,LEN(G55)-7)
=RIGHT(C55,LEN(C55)-10)

Lo que me va a llegar a algo como: 3,326,698,574.

Lo que me gustaría hacer es agregar todas las celdas usando =sum, pero no puedo hacer que funcione.

microsoft-excel worksheet-function

— usuario396885
fuente

1

Puedes obtener el número con

=VALUE(MID(LEFT(G55,LEN(G55)-7),FIND("(",G55)+1,99))

Si esto te deja con un error #VALOR, tu Excel no maneja automáticamente las comas dentro de tu texto. Si ese es el caso, agregue un sustituto:

=VALUE(SUBSTITUTE(MID(LEFT(G55,LEN(G55)-7),FIND("(",G55)+1,99),",","")

Digamos que este valor está en C55. Luego puede convertir esto a su notación original de la siguiente manera:

=ROUND(SUM(C55)/1024^3,3)&" GB ("&TEXT(SUM(C55),"#,###")&" bytes)"

Puede reemplazar C55 con el rango de sus datos.

— Freekvd
fuente

1

Puede reemplazar la referencia C55 en la segunda fórmula con la fórmula C55 para reducir esto a una fórmula. Sin embargo, su resultado es texto, que no suma, y su fórmula funcionará solo para valores en ese rango de tamaño. Aquí hay una manera de crear una fórmula genérica que funcione para valores de cualquier tamaño y le brinde resultados numéricos. Lo construiré paso a paso para que la acción sea más clara.

Siempre desea trabajar con el número completo que está dentro de los paréntesis. Para localizar eso independientemente del tamaño de los números, puede mirar entre el paréntesis abierto "(" y el espacio posterior. La ubicación del "(" es:

    FIND("(",G55)

Encontrar el espacio posterior comienza la búsqueda en esa ubicación, por lo que su ubicación es:

    FIND(" ",G55,FIND("(",G55))

Desea extraer su número del medio de una cadena, así que use la función MID:

    MID(G55,FIND("(",G55)+1,FIND(" ",G55,FIND("(",G55))-FIND("(",G55)-1)

Eso se extrae de la cadena en G55, comenzando en la posición después de "(" e incluyendo el número de caracteres en la diferencia entre las dos ubicaciones (ajustando el conteo para la posición del delimitador). Eso le da la versión de texto de el número. Para sumar los valores, debe convertirlo en un número:

    =VALUE(MID(G55,FIND("(",G55)+1,FIND(" ",G55,FIND("(",G55))-FIND("(",G55)-1))

Todo en la fórmula hace referencia a la celda G55, por lo que si los valores están en una columna, copie la fórmula en la columna auxiliar para obtener la lista de números extraídos que luego puede sumar.

— fijador1234
fuente