Voltear los ejes x e y en el gráfico de Excel

Esto no debería ser muy difícil, pero no puedo entender cómo hacerlo.

Tengo una mesa similar a esta

   %low %high
 0   0   12
 1  13   26
 ...
19  90   94
20  95  100

Cuando lo grafo, Excel por defecto tiene la primera columna en el eje xy traza la segunda y tercera columna como valores y. Quiero que la primera columna esté en el eje y en su lugar. Supongo que hay una manera fácil de hacer esto, pero no puedo resolverlo. La mayoría de las cosas que he encontrado al buscar han sugerido el botón "Cambiar fila / columna", pero eso hace algo más.

Gracias por la ayuda.

Puede seleccionar manualmente lo que desea graficar.

Aquí están mis datos de muestra:

Selecciono crear un gráfico de diagrama de dispersión. Al editar la fuente de datos, hago clic en el botón Agregar.

Puede seleccionar lo que quiera para el nombre de la serie, pero selecciono el encabezado de la columna. Los valores X son los valores en su columna X, por supuesto. Los valores Y son una de las columnas Y.

Repita el proceso para el segundo conjunto de datos.

Aquí hay una rutina simple de VBA que crea un gráfico de dispersión XY a partir de los datos que se organizan con Y en la primera columna y uno o más conjuntos de X en los datos posteriores. Seleccione el rango de datos o seleccione una sola celda dentro de ese rango y ejecute el código.

Sub ChartFromInput_YXX()
    ' assumes first column of input range has Y values
    ' assumes subsequent columns have X values
    ' assumes first row of input range has series

    Dim rngDataSource As Range
    Dim iDataRowsCt As Long
    Dim iDataColsCt As Integer
    Dim iSrsIx As Integer
    Dim chtChart As Chart
    Dim srsNew As Series

    If Not TypeName(Selection) = "Range" Then
        '' Doesn't work if no range is selected
        MsgBox "Please select a data range and try again.", _
            vbExclamation, "No Range Selected"
    Else
        Set rngDataSource = Selection
        If rngDataSource.Cells.Count = 1 Then
            ' expand to data range including active cell
            Set rngDataSource = rngDataSource.CurrentRegion
        End If
        With rngDataSource
            iDataRowsCt = .Rows.Count
            iDataColsCt = .Columns.Count
        End With

        '' Create the chart
        Set chtChart = ActiveSheet.Shapes.AddChart.Chart

        With chtChart
            .ChartType = xlXYScatterLines

            '' Remove any series created with the chart
            Do Until .SeriesCollection.Count = 0
                .SeriesCollection(1).Delete
            Loop

            For iSrsIx = 1 To iDataColsCt - 1
                '' Add each series
                Set srsNew = .SeriesCollection.NewSeries
                With srsNew
                    .Name = rngDataSource.Cells(1, 1 + iSrsIx)
                    .Values = rngDataSource.Cells(2, 1) _
                        .Resize(iDataRowsCt - 1, 1)
                    .XValues = rngDataSource.Cells(2, 1 + iSrsIx) _
                        .Resize(iDataRowsCt - 1, 1)
                End With
            Next
        End With
    End If
End Sub

Si necesita una tarea repetitiva, la solución aceptada puede llevar mucho tiempo. El gran Jon Peltier tiene un complemento simple para esto. Ver su página .

Como se indica en esta otra página de documentación :

Cambiar ejes XY

Este es un marcador de posición para la página de documentación para Cambiar ejes XY.

Es decir, no hay documentación disponible. Sin embargo, realmente vale la pena intentarlo. Es realmente fácil de aprender.

Para necesidades ocasionales de cambio de eje, este tutorial muestra la forma más fácil de hacerlo.

1. Haga clic con el botón derecho en el gráfico y haga clic en Seleccionar datos en el menú contextual.
2. En el cuadro de diálogo emergente Seleccionar origen de datos, haga clic para resaltar la columna Y y luego haga clic en el botón Editar en la sección Entradas de leyenda (Serie).
3. Ahora aparece el cuadro de diálogo Editar serie. Cambie los valores de la Serie X y de la Serie Y, y luego haga clic en los botones Aceptar sucesivamente para cerrar ambos cuadros de diálogo.

Vea el enlace para fotos.