¿Cómo escribo una fórmula en Excel que me permite evaluar si cada valor en una fila es VERDADERO?

3

Básicamente, quiero la forma más eficiente de hacer algo como lo siguiente de la manera más eficiente posible y con muchas más columnas:

=and(f2=true,g2=true,h2=true,i2=true)

Gracias.

microsoft-excel

— debryc
fuente

10

Puede hacerlo de manera muy concisa con una fórmula de matriz. Pegue lo siguiente en la barra de fórmulas y presione Ctrl+ Shift+ Enter.

=AND(F2:I2)

EDITAR:
en respuesta al comentario de Jerry, si el rango que está revisando contendrá algo más que valores booleanos, deberá usar una fórmula más específica (porque todo el texto, los espacios en blanco y los números que no sean iguales a 0 se evaluarán como TRUE). Lo siguiente solo considerará celdas con el valor booleano TRUEcomo verdadero.

=AND(F2:I2=TRUE)

Esto también debe ingresarse como una función de matriz presionando Ctrl+ Shift+ Enter.

Si por casualidad quiere contar ambos TRUEy 1como verdadero, puede usar esta fórmula de matriz más complicada (ingresada con Ctrl+ Shift+ Enter).

=AND(NOT(ISERROR(MATCH(F2:I2,{TRUE,1},0))))

— Excellll
fuente

Este es definitivamente el camino a seguir.

— LPChip

De alguna manera, tenía la impresión de que todas las fórmulas de matriz no funcionan AND(). ¡Resultó que eso solo es aplicable cuando hay más de una condición! +1 Sin embargo, prefiero las fórmulas sin matriz cuando sea posible.

— Jerry

@ Jerry Sé lo que quieres decir con ANDno trabajar en fórmulas de matriz. Funciona como un agregador (no estoy seguro si ese es el término apropiado) como SUM, MINy SUMPRODUCT, es decir, puede tomar una matriz como argumento, pero solo devuelve un valor, nunca una matriz de valores. Entonces, si intenta ANDentrar en servicio en la condición de una IFfórmula en una matriz, no devolverá la matriz de valores T / F que probablemente estaba buscando, sino más bien una sola T / F. Lo mismo vale para OR.

— Excellll

6

Podrías hacer algo así por más corto:

=COUNTIF(F2:I2,TRUE)=4

Esto cuenta el número de TRUEy verifica si hay 4.

O si no quieres 'contarlos' y poner el número ...

=COUNTIF(F2:I2,TRUE)=COUNTA(F2:I2)

Lo anterior no tendrá en cuenta las celdas en blanco. Si quieres contarlos también:

=COUNTIF(F2:I2,TRUE)=COUNTA(F2:I2)+COUNTBLANK(F2:I2)

— alemán
fuente

2

Otra opción es utilizar el hecho de que VERDADERO se evalúa a 1 y FALSO se evalúa a 0 en ciertas circunstancias.

Descripción de la evaluación VERDADERA y FALSA

Usando el enlace de arriba puedes usar la función

=product(F2:I2*1)

que evaluaría a 1 si todos son verdaderos y 0 si hay falsos o espacios en blanco.

esta función debe ingresarse presionando ctrl + shift + enter ya que es una fórmula de matriz.

— gtwebb
fuente

Pero si hay 1, y TRUEdentro de los datos, que la fórmula se tendrán en cuenta la 1tan TRUEasí, que no creo que se pretende. Pero bueno, si el rango de OP puede contener solo booleanos, no hay forma de que esto pueda salir mal.

— Jerry