ZSH: autocompletado de selección de menú para búsqueda de historial

1

ZSH tiene un potente menú de selección de autocompletado, por ejemplo, para elegir un directorio, elegir un proceso con kill (kill [tab] [tab]). Puede usar flechas para navegar por las opciones.

¿Es posible tener el menú emergente para la búsqueda del historial (CTRL + R) también? ¿De tal manera que el menú permita navegar por las coincidencias de la barra de búsqueda CTRL + R actual?

zsh

— Mikko Ohtamaa
fuente

3

zsh-navigation-toolshace algo como esto Si usa oh-my-zsh, solo necesita agregarlo zsh-navigation-toolsa plugins=(...)su .zshrcentonces ctrl-R le dará un historial de desplazamiento con arriba / abajo y búsqueda / filtrado. Puede usarlo sin oh-my-zsh, pero la configuración parece más trabajo.

— Miguel
fuente

1

No que yo sepa.

Quizás desee probar predict-on, lo que hace algo relacionado con lo que está preguntando:

autoload -U predict-on
zle -N predict-on
zle -N predict-off
bindkey '^X1' predict-on
bindkey '^X2' predict-off

— Francisco
fuente

Función interesante: nunca antes había oído hablar de eso.

— mpy

0

Eso es posible; en principio modifiqué la _killfinalización para que funcione también para eventos históricos.

Aquí hay un ejemplo; después de seleccionar una entrada, presiona [ENTER] una vez para aceptar el número de evento (la línea de comando lee y luego fe hc 780) y presiona [ENTER] nuevamente para ejecutar el comando. (Use en fclugar de hcsi desea modificar la línea de comando antes de la ejecución).

$ hc Makefile[TAB]
history event
 1906  9.3.2013 18:10  vi Makefile
 1867  9.3.2013 17:26  less Makefile
  780  3.2.2013 17:54  cat Makefile                
  776  3.2.2013 17:51  cat ../Makefile

Para usarlo, coloque los archivos adjuntos en un directorio en su $fpathy agregue estas líneas en su ~/.zshrc:

zstyle ':completion:*:historyevent' command 'fc -dE -lr 1'
zstyle ':completion:*:historyevent' sort no

Finalmente, comience una nueva zshsesión.

Cuidado, es una solución rápida y sucia, pero funcionó bien por algún tiempo.

_historyevent

#autoload

local out histevent list expl match desc listargs all nm ret=1

_tags historyevent || return 1

all=(-U)
match="*[[:blank:]]*[[/[:blank:]]$PREFIX*$SUFFIX*"
nm="$compstate[nmatches]"

out=( "${(@f)$(_call_program historyevent fc -l 2>/dev/null)}" )
desc="$out[1]"
out=( "${(@M)out[2,-1]:#${~match}}" )

histevent=( "${(@)${(@M)out##[^0-9]#[0-9]#}##*[[:blank:]]}" )

if zstyle -T ":completion:${curcontext}:historyevent" verbose; then
  list=( "${(@Mr:COLUMNS-1:)out}" )
  desc=(-ld list)
else
  desc=()
fi

_wanted processes expl 'history event' \
    compadd "$@" "$desc[@]" "$all[@]" -a - histevent && ret=0

if [[ -n "$all" ]]; then
  zstyle -s ":completion:${curcontext}:historyevent" insert-ids out || out=menu

  case "$out" in
  menu)   compstate[insert]=menu ;;
  single) [[ $compstate[nmatches] -ne nm+1 ]] && compstate[insert]= ;;
  *)      [[ ${#:-$PREFIX$SUFFIX} -gt ${#compstate[unambiguous]} ]] &&
              compstate[insert]=menu ;;
  esac
fi

return ret

_fc

#compdef fc

local curcontext="$curcontext" line state ret=1

_arguments -C \
   '-e[editor command]' \
   '-l[list last history events]' \
   '-n[suppress numbers]' \
   '-r[reverse order]' \
   '*:history event:->historyevent' && ret=0

if [[ -n "$state" ]]; then
  _alternative \
    'historyevent:: _historyevent' && ret=0
fi

return ret

— mpy
fuente