Mover ventanas usando el teclado ... ¿más rápido?

Me gusta usar los atajos de teclado porque es más rápido ya que no me obliga a mover las manos del teclado.

En Windows puedo usarlos para mover ventanas por el escritorio:

1. Presione Alt+ Spacepara abrir el menú común de Windows
2. Presione Mpara elegir el comando "Mover"
3. Navegar por la posición de la ventana con las teclas del cursor
4. Confirmar nueva posición con Enter

Además, para lograr una mayor precisión, puedo mantenerlo Ctrlmientras navego.

Ahora el problema es que el "paso" normal cuando me muevo es de aproximadamente 20 px, y mi escritorio es bastante grande, por lo que "caminar" en todo el camino lleva bastante tiempo. Este tipo de derrota el propósito de usar el teclado para estas tareas.

¿Es posible cambiar el tamaño de este paso para que tome menos pasos caminar la misma distancia? (Me imagino una configuración oculta en el registro de Windows ...?)

Intenté sostener Altmientras navegaba, pero no parece tener influencia en la velocidad.

Si tiene ganas de reelaborar por completo los paradigmas de ventanas hacia el mosaico dinámico, considere un script de AutoHotkey llamado " bug.n ". Te gustará si prefieres manipular ventanas mediante el teclado.

Moverse por el teclado como lo hace es preciso, pero es tedioso.

Si normalmente mueve sus ventanas a ciertas posiciones y tamaños, intente con GridMove . Puede definir su propia cuadrícula (posición y tamaños de ventana) o utilizar las predefinidas. Cada uno de estos se llama mosaico. Después de eso, puede ajustar cualquier ventana activa presionando Win + 2, donde 2 es el número de mosaico en el que desea que se ajuste. Presione Win + G para ver las fichas y sus números en la cuadrícula actual.

En Windows 7, puede usar la tecla de Windows + la flecha para mover las ventanas.

No estoy seguro de cuántos píxeles los desplaza a la vez, pero son más de 20.

No del todo sobre el tema, pero creo que sigue siendo relevante y vale la pena compartirlo.

Utilizo AutoHotKey y un script "KDEStyle" que encontré hace mucho tiempo y que he adaptado para mejorar el uso del mouse para este propósito.

• Win + Left Click
  • Le permite mover la ventana haciendo clic en cualquier lugar dentro de ella.
• Win + Right Click
  • Le permite cambiar el tamaño de la ventana utilizando la esquina más cercana, nuevamente haciendo clic en cualquier lugar dentro de ella.

Esto reduce significativamente la precisión requerida y, en mi opinión, hace que sea mucho más fácil y rápido usar el mouse para tales fines.

#LButton::
    MouseGetPos,KDE_X1,KDE_Y1,KDE_id
    WinGet,KDE_Win,MinMax,ahk_id %KDE_id%
    if KDE_Win
        return
    WinGetPos,KDE_WinX1,KDE_WinY1,,,ahk_id %KDE_id%
    loop {
        GetKeyState,KDE_Button,LButton,P
        if KDE_Button = U
            break
        MouseGetPos,KDE_X2,KDE_Y2
        KDE_X2 -= KDE_X1
        KDE_Y2 -= KDE_Y1
        KDE_WinX2 := (KDE_WinX1 + KDE_X2)
        KDE_WinY2 := (KDE_WinY1 + KDE_Y2)
        WinMove,ahk_id %KDE_id%,,%KDE_WinX2%,%KDE_WinY2%
    }
    return

#RButton::
    MouseGetPos,KDE_X1,KDE_Y1,KDE_id
    WinGet,KDE_Win,MinMax,ahk_id %KDE_id%
    if KDE_Win
        return
    WinGetPos,KDE_WinX1,KDE_WinY1,KDE_WinW,KDE_WinH,ahk_id %KDE_id%
    if (KDE_X1 < KDE_WinX1 + KDE_WinW / 2) {
        KDE_WinLeft := 1
    } else {
        KDE_WinLeft := -1
    }
    if (KDE_Y1 < KDE_WinY1 + KDE_WinH / 2) {
        KDE_WinUp := 1
    } else {
        KDE_WinUp := -1
    }
    loop {
        GetKeyState,KDE_Button,RButton,P
        if KDE_Button = U
            break
        MouseGetPos,KDE_X2,KDE_Y2
        WinGetPos,KDE_WinX1,KDE_WinY1,KDE_WinW,KDE_WinH,ahk_id %KDE_id%
        KDE_X2 -= KDE_X1
        KDE_Y2 -= KDE_Y1
        WinMove,ahk_id %KDE_id%,, KDE_WinX1 + (KDE_WinLeft+1)/2*KDE_X2
                                , KDE_WinY1 +   (KDE_WinUp+1)/2*KDE_Y2
                                , KDE_WinW  -     KDE_WinLeft  *KDE_X2
                                , KDE_WinH  -       KDE_WinUp  *KDE_Y2
        KDE_X1 := (KDE_X2 + KDE_X1)
        KDE_Y1 := (KDE_Y2 + KDE_Y1)
    }
    return

Las combinaciones de teclado estándar de Windows complementan esto y le permiten:

• Win+ Up/Down
  • Maximizar / Restaurar / Minimizar
• Win+ Left/Right
  • Cambiar el tamaño a la mitad izquierda / derecha de la pantalla
• Win+ Shift+ Left/Right
  • Mueve un monitor hacia la izquierda / derecha
• etc ...