¿Cómo puedo abrir un símbolo del sistema en la carpeta actual con un atajo de teclado?

¿Cómo puedo abrir un símbolo del sistema en la carpeta actual con un método abreviado de teclado en Windows 7?
¿Hay alguna forma de implementar esto?
Creo que Autohotkey podría hacer esto, pero no sé cómo.

Utilice esta combinación de teclas: Shift+ Menu, W,Enter

1. Shift+ Menu(alternativamente, Shift+ F10), (abre el menú extendido del botón derecho en la carpeta actual)

2. W (selecciona "Abrir ventana de comandos aquí"),

3. Enter(activa la selección; se requiere ya que "Nuevo" también se puede seleccionar con W)

La Menuclave se refiere a la clave especial introducida por Microsoft, generalmente a la derecha de la Winclave correcta .

Este acceso directo está disponible en una instalación predeterminada de Windows (7) sin ningún software de terceros.

El camino AHK. Solo necesita presionar Win+C (o lo que quiera definir como):

SetTitleMatchMode RegEx
return

; Stuff to do when Windows Explorer is open
;
#IfWinActive ahk_class ExploreWClass|CabinetWClass

    ; create new text file
    ;
    #t::Send !fwt

    ; open 'cmd' in the current directory
    ;
    #c::
        OpenCmdInCurrent()
    return
#IfWinActive


; Opens the command shell 'cmd' in the directory browsed in Explorer.
; Note: expecting to be run when the active window is Explorer.
;
OpenCmdInCurrent()
{
    ; This is required to get the full path of the file from the address bar
    WinGetText, full_path, A

    ; Split on newline (`n)
    StringSplit, word_array, full_path, `n

    ; Find and take the element from the array that contains address
    Loop, %word_array0%
    {
        IfInString, word_array%A_Index%, Address
        {
            full_path := word_array%A_Index%
            break
        }
    }  

    ; strip to bare address
    full_path := RegExReplace(full_path, "^Address: ", "")

    ; Just in case - remove all carriage returns (`r)
    StringReplace, full_path, full_path, `r, , all


    IfInString full_path, \
    {
        Run,  cmd /K cd /D "%full_path%"
    }
    else
    {
        Run, cmd /K cd /D "C:\ "
    }
}

Como beneficio adicional, el script anterior también crea un nuevo archivo de texto con este acceso directo: Win+T

Crédito a: Eli Bendersky

Presione Alt+ D, escriba cmdy presione Enter. Para más detalles, vea la publicación del blog aquí .

la forma nativa de hacer algo similar en windows7 es mantener presionado shiftmientras presiona el mouse derecho sobre la carpeta a la que desea "solicitar el comando" y aparecerá un nuevo elemento de menú en su menú contextual que le ofrece exactamente eso: "abra el símbolo del sistema aquí ".

si quieres una acción pura del teclado, tienes que hacer esto:

• abierto regedit
• ir HKEY_CLASSES_ROOT\Directory\shell\cmdy cambiar el nombre de la Extendedclave aExtended_save
• ir HKEY_CLASSES_ROOT\Drive\shell\cmdy renombrar el Extended key toExtended_save`

esto agrega la entrada "abrir ventana de comandos aquí" al menú contextual permanentemente. puede activar esta entrada presionando:

• alt
• suelta, se abre el menú contextual
• presione el carácter "subrayado" de la entrada "abrir ventana de comando aquí" o baje con las teclas del cursor y presione enter

el nombre de la entrada del menú se etiqueta según el idioma de su sistema operativo.

Una ruta alternativa es hacer esto:

• abra la carpeta que desee en el símbolo del sistema a través del explorador
• f4
• ctrla
• ctrlc
• winr
• cmd /k cd ctrlventer

que toma la ruta actual de la barra de direcciones del explorador y se ejecuta cmd /k cd PATH. con autohotkeys puedes hacer lo mismo, pero no sé las autohotkeys.

Desde how-to-open-cmd-in-current-folder-by-shortcut-windows-10

Si está utilizando Windows 8/10, hay una forma más rápida y original:

Alt+ F,P

Solo tres teclas y escriba dos veces, sin la ayuda de otro programa.

A partir de la última actualización de Windows 10, de la respuesta de Leftium Shift+ Menu, Wmétodo ya no funciona. Sin embargo, una pequeña modificación puede presentar una solución alternativa, aunque con algunas pulsaciones de teclas más.

El problema es que el símbolo del sistema ya no está disponible en el menú extendido de clic derecho. En cambio, ahora tiene Windows Powershell.

Shift+ Menu, Sabre Windows Powershell en la carpeta de destino. Una vez en Windows Powershell, escriba y cmdluego presioneEnter.

Esto le dará acceso al símbolo del sistema dentro de Windows Powershell.

PD

El método de Ashwin Nanjappa de Ctrl+ L, escribe y cmdluego presiona Entertrabajos. Sin embargo, es elegante solo si no tiene intención de volver a la ventana del Explorador de Windows para continuar navegando entre directorios. Desafortunadamente, el método aleja el cursor del Explorador de Windows de la ventana principal y requiere varias Tabpulsaciones de teclas para volver a donde puede navegar por las carpetas con las teclas de flecha. Esto puede ser frustrante ya que hay una confirmación visual limitada cuando se presionan esas Tabteclas.

Mientras que Windows Powershell funciona de manera idéntica a la línea de comandos, he encontrado al menos un caso en el que Windows Powershell estaba leyendo erróneamente mis @tags (cuando estaba generando javadocs) y no producía el resultado deseado. Al escribir y cmdluego Intro en Windows Powershell, puede utilizar el símbolo del sistema en su lugar, que supera estos problemas.

La forma más fácil es ir a la barra de direcciones del explorador de Windows y escribir cmd, abrirá el símbolo del sistema inmediatamente desde esa ubicación.

Script AutoHotKey para abrir el símbolo del sistema utilizando el método de @ Ashwin

Abra la consola Powershell usando Win P

#P::
{
    Send !D
    Send powershell
    Send {Enter}    
    return
}

Abrir símbolo del sistema usando Win C

#C::
{
    Send !D
    Send CMD
    Send {Enter}    
    return
}

Una secuencia de comandos AHK más simple que la de la pregunta seleccionada

#c::cmdHere()

cmdHere() {
    If WinActive("ahk_class CabinetWClass") || WinActive("ahk_class ExploreWClass") {
        WinHWND := WinActive()
        For win in ComObjCreate("Shell.Application").Windows
            If (win.HWND = WinHWND) {
                dir := SubStr(win.LocationURL, 9) ; remove "file:///"
                dir := RegExReplace(dir, "%20", " ")
                Break
            }
    }
    Run, cmd, % dir ? dir : A_Desktop
}

fuente de aquí: https://autohotkey.com/boards/viewtopic.php?t=5796

Si está utilizando una versión de Windows en alemán, puede hacer esto:

Presione Alt+ D,E

Alt+ Dabre un menú donde puede seleccionar algunas otras cosas además del cmd

Para AHK, el siguiente es mi enlace:

#c::
Run, C:\Windows\system32\cmd.exe
return

Esto no abre la carpeta actual, pero es útil.