Aquí hay un par de métodos. La pregunta no es clara sobre si está replicando la fórmula en las columnas de una sola fila o hacia abajo en las filas de una sola columna. Lo mostraré para ambos.
Alternativa 1
Este enfoque analiza las celdas anteriores para descubrir qué se necesita. Dado que el patrón se basa en dos celdas, debe escribir las dos primeras ( I1Ay I1B). Ingrese esta fórmula en la siguiente celda.
Si se cruza: si las dos primeras celdas son A1 y B1, esto iría en C1:
="I" & IF(MID(A1,2,1)=MID(B1,2,1),1,0) + MID(B1,2,1) & RIGHT(A1,1)
Si baja: si las dos primeras celdas son A1 y A2, esto iría en A3:
="I" & IF(MID(A1,2,1)=MID(A2,2,1),1,0) + MID(A2,2,1) & RIGHT(A1,1)
Esto utiliza funciones de cadena para extraer los caracteres que cambian, ajustarlos y volver a unir las piezas (los símbolos concatenan las piezas). El primer personaje es constante.
Para el segundo carácter, analiza si el número (carácter del medio) era el mismo para las dos celdas anteriores. Si es así, es hora de agregar 1. De lo contrario, permanece igual.
Como el último carácter se repite cada otra celda, solo usa el valor de dos celdas anteriores.
Una vez que tenga la fórmula en la tercera celda, puede copiarla tanto como la necesite. El método 1 no le importa en qué parte de la hoja de trabajo lo pones.
Alternativa 2
Este enfoque utiliza algunos trucos aritméticos para descubrir qué ocurre en cada celda.
El número en el medio aumenta por 1cada dos columnas (o filas). La función COLUMNA le da el número de la columna (A = 1, B = 2, etc.). La función de fila hace lo mismo para el número de fila. Si comienza en la columna A (o fila 1), ya tiene el número inicial correcto. Si este patrón comienza en una columna (o fila) posterior, deberá restar 1 menos que el número de la columna (o fila) para obtener un valor inicial de 1. Al dividir por 2 y al redondear se repite el valor de dos columnas ( o filas), luego incrementos.
Si va al otro lado: si comienza en la columna A, esta parte de la fórmula sería:
ROUND(COLUMN()/2,0)
Si comienza en la columna C (la tercera columna), la fórmula sería:
ROUND((COLUMN()-2)/2,0)
Si baja: si comienza en la fila 1, esta parte de la fórmula sería:
ROUND(ROW()/2,0)
Si comienza en digamos la fila 3, la fórmula sería:
ROUND((ROW()-2)/2,0)
Mostraré las versiones simples en la fórmula completa a continuación; simplemente sustituya la versión ajustada si comienza en una columna (o fila) diferente.
La letra al final se alterna, por lo que puede basarla en números impares o pares de columnas (o filas).
Si va a cruzar: si comienza en una columna impar, esta pieza sería:
IF(MOD(COLUMN(),2)=0,"B","A")
Si el número de columna inicial es par, sería:
IF(MOD(COLUMN(),2)=0,"A","B")
Si baja: si comienza en una fila impar, esta pieza sería:
IF(MOD(ROW(),2)=0,"B","A")
Si el número de la fila inicial es par, sería:
IF(MOD(ROW(),2)=0,"A","B")
La función MOD le da el resto después de dividir el número de columna (o fila) por 2. Un número de columna (o fila) que sea par tendrá el resto de 0uno impar 1. Entonces, secuencia las opciones "A" y "B" en función de eso. Para el siguiente ejemplo consolidado, mostraré la versión impar.
Ponerlo junto te da:
Si va a cruzar:
="I" & ROUND(COLUMN()/2,0) & IF(MOD(COLUMN(),2)=0,"B","A")
Si baja:
="I" & ROUND(ROW()/2,0) & IF(MOD(ROW(),2)=0,"B","A")
Ingrese la versión apropiada para la primera celda, luego cópiela en todas las celdas que necesite.
