¿Qué fórmula devolverá un código designado para el valor más alto en un conjunto de celdas? [cerrado]

Quiero devolver el valor más alto en un conjunto de celdas con un código representativo. Una imagen vale más que mil palabras, así que he agregado una para ti a continuación:

Lo que ves en la imagen (columna T, donde la letra se relaciona con uno de los encabezados y muestra cuál es el valor más alto de las tres columnas anteriores) se hizo a mano. No quiero hacer eso por el resto porque tomaría mucho tiempo.

¿Cuál es la fórmula más simple y fácil para lograr esto para alguien que usa Excel 2007? (Si pudiera agregar un poco de explicación con su fórmula, sería aún mejor, pero no necesario).

worksheet-function microsoft-excel-2007

— Lisa Beck
fuente

Tenga en cuenta que superuser.com no es un servicio gratuito de escritura de script / código. Si nos dice lo que ha intentado hasta ahora (incluya los scripts / código que ya está usando) y dónde está atascado, entonces podemos intentar ayudarlo con problemas específicos. También deberías leer ¿Cómo hago una buena pregunta? .

— DavidPostill

Gracias por el comentario, @DavidPostill. No he hecho muchas preguntas en este foro y dado que mis una o dos preguntas sobre fórmulas fueron respondidas tan rápidamente y sin ninguna advertencia sobre el uso de esto para un "servicio gratuito de escritura de código / script", me sorprendió un poco para ver este tipo de comentarios, especialmente cuando he intentado ayudar a otros ofreciendo una solución propia en al menos una ocasión. Sin embargo, la página a la que me refirió era buena y disfruté leyéndola. Sin embargo, no creo que mi pregunta aquí esté realmente en desacuerdo con ninguno de los consejos que brinda.

— Lisa Beck

En cuanto al primer punto de la página a la que me refirió (búsqueda e investigación), siempre hago algo de eso antes de molestarme en este intercambio de pila, y luego trato de asegurarme de que mi pregunta aún no haya sido abordado a través de este foro. La cantidad que hago depende de cuán difícil creo que responda mi pregunta en relación con la profundidad y amplitud del conocimiento agrupado que creo que podría existir en superuser.com. A menudo no intento "enturbiar las aguas" con mis a veces torpes intentos de improvisar una fórmula que funcione.

— Lisa Beck

Pero solo para usted, @DavidPostill, compartiré algunos de los trabajos "detrás de escena" que se realizaron antes de decidir publicar esta pregunta. Después de visitar varias páginas web con algunas fórmulas realmente complicadas, finalmente decidí tirar la toalla e intentar algo fuera de mi cabeza. Entonces arrojé esto: = IF (Q2> R2, "N").

— Lisa Beck

Eso funcionó, pero cuando intenté agregar una tercera columna de información a esa fórmula condicional, seguí recibiendo mensajes de error tras mensaje de error. A pesar de que no pude encontrar una fórmula que funcionara, tengo la sensación de que esto no sería tan difícil para un súper usuario experimentado, por lo que no pasé mucho tiempo tratando de resolverlo por mi cuenta. Me ha impresionado bastante la experiencia de los usuarios en este foro, por lo que realmente me sorprendería si esto fuera algo que desconcierta a esta comunidad.

— Lisa Beck

Respuestas:

Como no especificó qué sucede en un empate, voy a suponer que el resultado debería ser NBT si hay un empate en las tres columnas.

Encuentra el valor máximo:

Usa esta fórmula:
```
=MAX(Q2:S2)
```
Esto da el valor máximo. (Esto supone que es para usar en T2)

Use el administrador de nombres para dar a esta fórmula el nombre MaxV o simplemente use la fórmula misma.
Primero SI:
```
=IF(Q2=MaxV,"N","")
```
Este IF () imprime una N o nada
Haga una fórmula para otras columnas y combine en una sola ecuación:
```
=IF(Q2=MaxV,"N","") & IF(R2=MaxV,"B","") & IF(S2=MaxV,"T","")
```

Si no desea utilizar el administrador de nombres, la fórmula completa es:

=IF(Q2=MAX(Q2:S2),"N","") & IF(R2=MAX(Q2:S2),"B","") & IF(S2=MAX(Q2:S2),"T","")

El &se usa para unir dos letras juntas de forma similar a cómo se usa un + para agregar dos números.

— bvaughn
fuente

Todavía no he probado su fórmula, pero ya estoy impresionado con su respuesta por su simplicidad y el uso de las características de Excel un poco más comunes para el usuario promedio. Estoy familiarizado con las funciones MIN / MAX hasta cierto punto, pero por alguna razón no pensé en ellas en absoluto al intentar resolver esto. Quizás estaba demasiado concentrado en la redacción de la fórmula condicional y por qué mis diversos intentos no estaban funcionando en lugar de las características ya existentes de Excel que podrían ayudarme a hacer más con menos.

— Lisa Beck

En cuanto a cualquier "vínculo", tomé medidas para asegurar que no hubiera ninguno, pero me gusta su solución propuesta en tal caso. Voy a probar tu fórmula ahora para ver si funciona. Te diré lo que pasa. Muchas gracias por haber hecho el intento.

— Lisa Beck

Eres brillante, @bvaughn. Tu fórmula funciona como un encanto.

— Lisa Beck

La respuesta de bvaughn es agradable, limpia y simple, especialmente si solo tiene unas pocas columnas. También es intuitivamente escalable si agrega más columnas. Sin embargo, si tiene muchas columnas, ese enfoque puede comenzar a ser difícil de manejar.

Aquí hay un enfoque diferente que se escala mejor si alguna vez tiene que expandir el problema con más columnas.

=CHOOSE(MATCH(MAX(Q2:S2),Q2:S2,0),"N","B","T")

Explicación, trabajando de adentro hacia afuera:

MAX(Q2:S2) identifica el valor máximo en el rango.
MATCH(MAX(Q2:S2),Q2:S2,0) localiza ese valor en el rango, dándole un número de posición.
CHOOSE(position,"N","B","T") selecciona de la lista de valores de salida usando esa misma posición relativa.

Este tipo de fórmula puede manejar una gran cantidad de columnas simplemente agregando los resultados a la lista (y ajustando el rango, por supuesto). La porción del caballo de batalla no cambia cuando las columnas crecen. La fórmula se mantiene compacta porque lo único que crece a medida que agrega columnas es la lista de valores de salida.

Solución alternativa

La función ELEGIR solo es necesaria porque está utilizando etiquetas diferentes de los encabezados de columna. Si usa los encabezados de columna ("Noticias", "Libros", "Tweets" en este caso), puede usar una fórmula genérica que solo haga referencia a los rangos:

=INDEX(Q$1:S$1,1,MATCH(MAX(Q2:S2),Q2:S2,0))

La ubicación de la posición del número más alto es la misma que antes, pero se usa para seleccionar de los encabezados en la primera fila usando ÍNDICE. Esta fórmula permanecería igual para cualquier número de columnas, solo especificando el rango.

— fijador1234
fuente

Una buena alternativa elegante a mi método. Sin embargo, ii maneja los lazos de manera diferente. Si hay un enlace de salidas de mina (NT) donde esto generaría (N). Dependería de dónde se use esto si los lazos fueran algo con lo que preocuparse.

— bvaughn

@bvaughn, tienes razón. Si puede haber vínculos, su respuesta lo maneja muy bien y la mía no. Supongo que eso también explica por qué su respuesta recibió el comentario "Eres brillante"; Obviamente eso es verdad. :-)

— fijador1234