calculando Golf Handicap

Actualmente utilizamos la siguiente fórmula y funciona muy bien:

=IF(COUNTIF(D4:AB4,">0")<3,C4,IF((((SUM(D4:AB4)-(COUNTIF(D4:AB4,">0")*36))/COUNTIF(D4:AB4,">0")))*0.9>20,20,(((SUM(D4:AB4)-(COUNTIF(D4:AB4,">0")*36))/COUNTIF(D4:AB4,">0")))*0.9))

Lo que se dice es que debe jugar al menos 3 veces antes de que la fórmula vuelva a calcular una nueva desventaja; de lo contrario, se quedará con (C4) con lo que comenzó y solo usamos el 90% de su promedio para calcular su discapacidad.

Sin embargo, después de muchas semanas de juego, la desventaja apenas cambia debido a la gran cantidad de entradas; Para mantener actualizada la desventaja, queremos que use los 5 puntajes más actuales y, sin embargo, haga todo el resto que la fórmula hace actualmente.

Debido a que las personas faltan o están ausentes, no habrá publicaciones en algunas semanas, por lo que queremos omitir los espacios en blanco y solo usar las semanas publicadas

podrías usar la fórmula:

=MIN(IF(COUNTIF(D4:AB4,">0")<3,C4,IF(COUNTIF(D4:AB4,">0")<=5,SUM(IF(D4:AB4>0,D4:AB4-36))/COUNTIF(D4:AB4,">0"),SUM(IF(COLUMN(D4:AB4)=LARGE(IF(D4:AB4>0,COLUMN(D4:AB4)),ROW($1:$5)),D4:AB4-36)/5))*0.9),20)

Esta es una fórmula de matriz y debe confirmarse con ctrl+ shift+ enter!

Esta fórmula simplemente puede copiarse según lo necesite.

El orden de las acciones:

• Si el valor elegido es superior a 20, muestre solo 20 (también si 21+ está en C4)
  • menos de 3 entradas:
    • elige el valor de C4
  • más de o igual a 3 entradas
    • menos de o igual a 5 entradas
      • reste 36 de cada valor que es mayor 0
      • resumir todo
      • dividir por la cantidad de números
    • más de 5 entradas
      • si el valor es> 0, muestre el número de columna
      • obtener los 5 números de columna más grandes de esa lista
      • si el número de columna de la columna está en esa lista: devuelva el valor restado por 36
      • resumir todo
      • dividir por cinco
    • multiplicar por 0.9