¿Cómo escribir el script de espera para instalar mariadb?

Medio ambiente: centos7 + mariadb5.5.64.
Permítanme mostrar la información de instalación en la pantalla cuando se ejecute mysql_secure_installation.

# mysql_secure_installation

NOTE: RUNNING ALL PARTS OF THIS SCRIPT IS RECOMMENDED FOR ALL MariaDB
      SERVERS IN PRODUCTION USE!  PLEASE READ EACH STEP CAREFULLY!

In order to log into MariaDB to secure it, we'll need the current
password for the root user.  If you've just installed MariaDB, and
you haven't set the root password yet, the password will be blank,
so you should just press enter here.

Enter current password for root (enter for none): 
OK, successfully used password, moving on...

Setting the root password ensures that nobody can log into the MariaDB
root user without the proper authorisation.

Set root password? [Y/n] y
New password: 
Re-enter new password: 
Password updated successfully!
Reloading privilege tables..
 ... Success!


By default, a MariaDB installation has an anonymous user, allowing anyone
to log into MariaDB without having to have a user account created for
them.  This is intended only for testing, and to make the installation
go a bit smoother.  You should remove them before moving into a
production environment.

Remove anonymous users? [Y/n] y
 ... Success!

Normally, root should only be allowed to connect from 'localhost'.  This
ensures that someone cannot guess at the root password from the network.

Disallow root login remotely? [Y/n] y
 ... Success!

By default, MariaDB comes with a database named 'test' that anyone can
access.  This is also intended only for testing, and should be removed
before moving into a production environment.

Remove test database and access to it? [Y/n] y
 - Dropping test database...
 ... Success!
 - Removing privileges on test database...
 ... Success!

Reloading the privilege tables will ensure that all changes made so far
will take effect immediately.

Reload privilege tables now? [Y/n] y
 ... Success!

Cleaning up...

All done!  If you've completed all of the above steps, your MariaDB
installation should now be secure.

Thanks for using MariaDB!

Escribo un script de automatización para instalar mariadb.

  vim secure.exp
  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? [Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? [Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? [Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? [Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? [Y/n]" {send "y\r";exp_continue}
  }

Para ejecutar /usr/bin/expect secure.exp, me encuentro con el error:

spawn mysql_secure_installation
invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
          "Enter current password for root (enter for none): " {send "\r";exp_continue}
          "Set root password? [Y/n] " {send "y\r";exp..."
    (file "secure.exp" line 3)

No sirve de nada escribir de la siguiente manera:

  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? \\[Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? \\[Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? \\[Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? \\[Y/n]" {send "y\r";exp_continue}
  }

Mismo error:

invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_conti..."
    (file "secure.exp" line 3)

¿Cómo arreglar mi script exp entonces?

Estos scripts esperan para recibir una salida opcional ( timeout -1significa "sin tiempo de espera") y pueden distinguir diferentes respuestas, ya que es requerido por yum instally mysql_secure_installation. Con #!/bin/expect -fcomo shebang, los scripts se pueden ejecutar cuando se configuraron chmod +x.

A) Para empezar, mariadb_yum.exp(requiere suo sudo):

#!/bin/expect -f
set timeout 30
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_yum.exp \[linux sudo password\]\n"
    exit 1
}
set USERNAME "[exec whoami]"
set PASSWORD [lindex $argv 0];

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/$USERNAME/mariadb_install.log"

spawn sudo yum -y install MariaDB-server
set yum_spawn_id $spawn_id

# On GCE it will never ask for a sudo password:
expect -ex "\[sudo\] password for $USERNAME: " {
   exp_send "$PASSWORD\r"
}

expect {
    # when the package was already installed
    -ex "Nothing to do" {
        send_user "package was already installed\n"
    }
    # when the package had been installed
    -ex "Complete!" {
        send_user "package had been installed\n"
    }
}

expect eof
close $yum_spawn_id
exit 0

B) Y luego mariadb_sec.exp(no requiere sudo):

#!/bin/expect -f
set timeout 1
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_sec.exp \[mysql root password\]\n"
    exit 1
}
set PASSWORD [lindex $argv 0];

spawn mysql_secure_installation
set mysql_spawn_id $spawn_id

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/[exec whoami]/mariadb_install.log"

# when there is no password set, this probably should be "\r"
expect -ex "Enter current password for root (enter for none): "
exp_send "$PASSWORD\r"

expect {
    # await an eventual error message
    -ex "ERROR 1045" {
        send_user "\nMariaDB > An invalid root password had been provided.\n"
        close $mysql_spawn_id
        exit 1
    }
    # when there is a root password set
    -ex "Change the root password? \[Y/n\] " {
        exp_send "n\r"
    }
    # when there is no root password set (could not test this branch).
    -ex "Set root password? \[Y/n\] " {
        exp_send "Y\r"
        expect -ex "New password: "
        exp_send "$PASSWORD\r"
        expect -ex "Re-enter new password: "
        exp_send "$PASSWORD\r"
    }
}
expect -ex "Remove anonymous users? \[Y/n\] "
exp_send "Y\r"
expect -ex "Disallow root login remotely? \[Y/n\] "
exp_send "Y\r"
expect -ex "Remove test database and access to it? \[Y/n\] "
exp_send "Y\r"
expect -ex "Reload privilege tables now? \[Y/n\] "
exp_send "Y\r"

expect eof
close $mysql_spawn_id
exit 0

Para fines de depuración, o para validar la respuesta, se puede ejecutar expectcon nivel de registro strace 4. Esto es probablemente tan confiable como una fuente puede obtener, cuando se trata de escribir expectscripts, ya que muestra muy bien lo que está sucediendo y lo más importante, en qué orden suceden las cosas:

expect -c "strace 4" ./mariadb_yum.exp [linux sudo password]
expect -c "strace 4" ./mariadb_sec.exp [mysql root password]

La instrucción set exp_internal 1se puede utilizar para obtener resultados para la coincidencia de expresiones regulares.

Una posible fuente de confusión podría ser, donde uno genera los procesos, ya que uno puede generar varios procesos en varios hosts, por ejemplo. sshlocalmente y luego yumy de mysql_secure_installationforma remota. Agregado $spawn_idal guión; la última closellamada puede ser redundante, ya que ya lo es EOF(solo para mostrar cómo spawny closeprocesos):

Thanks for using MariaDB!
 1  close $mysql_spawn_id
 1  exit 0
 2  rename _close.pre_expect close

Conclusión: el mariadb_sec.expscript probablemente podría mejorarse aún más, por ejemplo. cuando al principio no envía una contraseña y ve lo que sucede, luego envía la contraseña activada ERROR 1045(cuando ya se había establecido una contraseña anteriormente). Puede suponerse que se debe establecer la contraseña cuando el servidor se acaba de instalar (excepto que yum reinstallofrece el mismo resultado). Simplemente no tenía un contenedor CentOS en blanco para probar todos los casos. A menos que se ejecute en un rootshell, sería necesario pasar ambos tipos de contraseñas en un script para automatizar esto desde la instalación hasta la post-instalación.

Probablemente valga la pena señalar que en GCE, sudono pediría una contraseña; De hecho, existen pequeñas diferencias basadas en el entorno, ya que estas imágenes de contenedor de CentOS se comportan de manera diferente. En tal caso (dado que no hay sudetección de imagen de contenedor o en su lugar), el mariadb_yum.expscript puede bloquearse durante 30segundos y luego continuar.

Las fuentes más acreditadas que puedo ofrecer son el expectmanual, escrito por Don Libes @ NIST y el manual TCL / TK para expect, junto con su proyecto SourceForge casualmente llamado expect.

No solo se utilizan corchetes para la sustitución de comandos, sino que también son especiales para los patrones globales .

Puede usar el -exactinterruptor mientras escapa entre corchetes entre comillas:

spawn mysql_secure_installation
expect {
    ...
    -exact "Set root password? \[Y/n\] " {send "y\r";exp_continue}
    ...
}

O use llaves en lugar de comillas:

spawn mysql_secure_installation
expect {
    ...
    {Set root password? \[Y/n\] } {send "y\r";exp_continue}
    ...
}

Para su información, puede tener el script esperado generado para usted usando autoexpect:

autoexpect ./mysql_secure_installation

Esto generará un script de espera llamado script.expen su directorio de trabajo actual.