¿Cómo evito que TStrings.SaveToFile cree una línea vacía final?

Tengo un archivo .\input.txtcomo este:

aaa
bbb
ccc

Si lo leo usando TStrings.LoadFromFiley lo escribo de nuevo (incluso sin aplicar ningún cambio) TStrings.SaveToFile, crea una línea vacía al final del archivo de salida.

var
  Lines : TStrings;
begin
  Lines := TStringList.Create;
  try
    Lines.LoadFromFile('.\input.txt');

    //...

    Lines.SaveToFile('.\output.txt');
  finally
    Lines.Free;
  end;
end;

Se puede observar el mismo comportamiento utilizando la TStrings.Textpropiedad que devolverá una cadena que contiene una línea vacía al final.

Para Delphi 10.1 y posteriores hay una propiedad que TrailingLineBreakcontrola este comportamiento.

Cuando la propiedad TrailingLineBreak es True (valor predeterminado), la propiedad Text contendrá un salto de línea después de la última línea. Cuando es falso, el valor del texto no contendrá el salto de línea después de la última línea. Esto también puede controlarse mediante la opción soTrailingLineBreak.

Para Delphi 10.1 (Berlín) o posterior, la mejor solución se describe en la respuesta de Uwe.

Para versiones anteriores de Delphi, encontré una solución creando una clase secundaria TStringListy anulando la TStrings.GetTextStrfunción virtual, pero me alegrará saber si hay una mejor solución o si alguien más encontró algo incorrecto en mi solución

Interfaz:

  uses
    Classes;

  type
    TMyStringList = class(TStringList)
    private
      FIncludeLastLineBreakInText : Boolean;
    protected
      function GetTextStr: string; override;
    public
      constructor Create(AIncludeLastLineBreakInText : Boolean = False); overload;
      property IncludeLastLineBreakInText : Boolean read FIncludeLastLineBreakInText write FIncludeLastLineBreakInText;
    end;

Implementación:

uses
  StrUtils;      

constructor TMyStringList.Create(AIncludeLastLineBreakInText : Boolean = False);
begin
  inherited Create;

  FIncludeLastLineBreakInText := AIncludeLastLineBreakInText;
end;

function TMyStringList.GetTextStr: string;
begin
  Result := inherited;

  if(not IncludeLastLineBreakInText) and EndsStr(LineBreak, Result)
  then SetLength(Result, Length(Result) - Length(LineBreak));
end;

Ejemplo:

procedure TForm1.Button1Click(Sender: TObject);
var
  Lines : TStrings;
begin
  Lines := TMyStringList.Create();
  try
    Lines.LoadFromFile('.\input.txt');
    Lines.SaveToFile('.\output.txt');
  finally
    Lines.Free;
  end;
end;