Vim: creación de directorios principales al guardar

Si invoco vim foo/bar/somefilepero foo/baraún no existo, Vim se niega a guardar.

Sé que podría cambiar a un shell o hacerlo :!mkdir foo/bardesde Vim, pero soy vago :) ¿Hay alguna manera de hacer que Vim lo haga automáticamente cuando guarda el búfer?

augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * if expand("<afile>")!~#'^\w\+:/' && !isdirectory(expand("%:h")) | execute "silent! !mkdir -p ".shellescape(expand('%:h'), 1) | redraw! | endif
augroup END

Tenga en cuenta las condiciones: expand("<afile>")!~#'^\w\+:/'evitará que vim cree directorios para archivos como ftp://*y !isdirectoryevitará llamadas costosas a mkdir.

Actualización : solución ligeramente mejor que también comprueba el tipo de búfer no vacío y utiliza mkdir():

function s:MkNonExDir(file, buf)
    if empty(getbufvar(a:buf, '&buftype')) && a:file!~#'\v^\w+\:\/'
        let dir=fnamemodify(a:file, ':h')
        if !isdirectory(dir)
            call mkdir(dir, 'p')
        endif
    endif
endfunction
augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * :call s:MkNonExDir(expand('<afile>'), +expand('<abuf>'))
augroup END

Según las sugerencias de mi pregunta, esto es lo que terminé con:

function WriteCreatingDirs()
    execute ':silent !mkdir -p %:h'
    write
endfunction
command W call WriteCreatingDirs()

Esto define el :Wcomando. Idealmente, me gustaría tener todos :w!, :wq, :wq!, :walletc funcionar de la misma, pero no estoy seguro si es posible sin reimplementar básicamente a todos con funciones personalizadas.

Agregué esto a mi ~ / .vimrc

cnoremap mk. !mkdir -p <c-r>=expand("%:h")<cr>/

Si necesito crear el directorio en el que estoy, escribo :mk.y lo reemplaza con "! Mkdir -p / ruta / a / mi / archivo /" y me permite revisar el comando antes de invocarlo.

Hice :saveas!crear el directorio si faltaba: https://github.com/henrik/dotfiles/commit/54cc9474b345332cf54cf25b51ddb8a9bd00a0bb

Este código le pedirá que cree el directorio con :w, o simplemente lo haga con :w!:

augroup vimrc-auto-mkdir
  autocmd!
  autocmd BufWritePre * call s:auto_mkdir(expand('<afile>:p:h'), v:cmdbang)
  function! s:auto_mkdir(dir, force)
    if !isdirectory(a:dir)
          \   && (a:force
          \       || input("'" . a:dir . "' does not exist. Create? [y/N]") =~? '^y\%[es]$')
      call mkdir(iconv(a:dir, &encoding, &termencoding), 'p')
    endif
  endfunction
augroup END

Creo que logré hacer esto en tres líneas, combinando lo que otros dicen en esta respuesta.

Esto parece funcionar:

if has("autocmd")
  autocmd BufWritePre * :silent !mkdir -p %:p:h
end

Intenta crear la carpeta automáticamente al guardar un búfer. Si sucede algo malo (es decir, problemas de permisos), simplemente se cerrará y dejará que falle la escritura del archivo.

Si alguien ve defectos obvios, publique un comentario. No estoy muy versado en vimscript.

EDITAR: Notas gracias a ZyX

• Esto no funcionará si sus carpetas tienen espacios (aparentemente no se escapan correctamente o algo así)
• O si está haciendo pseudo archivos.
• O si está obteniendo su vimrc.
• Pero hijo, es corto.