Agregó un botón a su DataGridViewy desea ejecutar un código cuando se hace clic.
Fácil, solo sigue estos pasos:
No hacer:
Primero, esto es lo que NO debes hacer:
Evitaría las sugerencias en algunas de las otras respuestas aquí e incluso las que proporciona la documentación de MSDN para codificar el índice o el nombre de la columna para determinar si se hizo clic en un botón. El evento click se registra para toda la cuadrícula, por lo que de alguna manera debe determinar que se hizo clic en un botón, pero no debe hacerlo asumiendo que su botón vive en un nombre o índice de columna en particular ... hay una manera más fácil ...
Además, tenga cuidado con el evento que desea manejar. Nuevamente, la documentación y muchos ejemplos se equivocan. La mayoría de los ejemplos manejan el CellClickevento que se disparará:
cuando se hace clic en cualquier parte de una celda.
... pero también se disparará cada vez que se haga clic en el encabezado de la fila . Esto requiere agregar código adicional simplemente para determinar si el e.RowIndexvalor es menor que 0
En su lugar, maneje lo CellContentClickque solo ocurre:
cuando se hace clic en el contenido dentro de una celda
Por alguna razón, el encabezado de la columna también se considera 'contenido' dentro de una celda, por lo que aún tendremos que verificarlo a continuación.
Dos:
Entonces, esto es lo que debes hacer:
Primero, envíe el remitente a escribir DataGridViewpara exponer sus propiedades internas en tiempo de diseño. Puede modificar el tipo en el parámetro, pero eso a veces puede hacer que agregar o quitar controladores sea complicado.
A continuación, para ver si se hizo clic en un botón, solo verifique para asegurarse de que la columna que genera el evento sea de tipo DataGridViewButtonColumn. Debido a que ya enviamos al remitente a escribir DataGridView, podemos obtener la Columnscolección y seleccionar la columna actual usando e.ColumnIndex. Luego verifique si ese objeto es de tipo DataGridViewButtonColumn.
Por supuesto, si necesita distinguir entre varios botones por cuadrícula, puede seleccionar según el nombre de la columna o el índice, pero esa no debería ser su primera comprobación. Siempre asegúrese de hacer clic primero en un botón y luego maneje cualquier otra cosa de manera apropiada. En la mayoría de los casos en los que solo tiene un solo botón por cuadrícula, puede saltar directamente a las carreras.
Poniendolo todo junto:
C # :
private void dataGridView1_CellContentClick(object sender, DataGridViewCellEventArgs e)
{
var senderGrid = (DataGridView)sender;
if (senderGrid.Columns[e.ColumnIndex] is DataGridViewButtonColumn &&
e.RowIndex >= 0)
{
//TODO - Button Clicked - Execute Code Here
}
}
VB :
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso
e.RowIndex >= 0 Then
'TODO - Button Clicked - Execute Code Here
End If
End Sub
Actualización 1 - Evento personalizado
Si desea divertirse un poco, puede agregar su propio evento para que se genere cada vez que se hace clic en un botón en DataGrid. No puede agregarlo a DataGrid en sí, sin desordenarse con la herencia, etc., pero puede agregar un evento personalizado a su formulario y activarlo cuando sea apropiado. Es un poco más de código, pero lo bueno es que ha separado lo que quiere hacer cuando se hace clic en un botón con la forma de determinar si se hizo clic en un botón.
Simplemente declare un evento, créelo cuando sea apropiado y manejelo. Se verá así:
Event DataGridView1ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent DataGridView1ButtonClick(senderGrid, e)
End If
End Sub
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) Handles Me.DataGridView1ButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
Actualización 2 - Cuadrícula extendida
Lo que sería genial es si estuviéramos trabajando con una grilla que acaba de hacer estas cosas por nosotros. Podríamos responder a la pregunta inicial fácilmente: you've added a button to your DataGridView and you want to run some code when it's clicked. Aquí hay un enfoque que extiende el DataGridView. Puede que no valga la pena tener que entregar un control personalizado con cada biblioteca, pero al menos reutiliza al máximo el código utilizado para determinar si se hizo clic en un botón.
Simplemente agregue esto a su ensamblaje:
Public Class DataGridViewExt : Inherits DataGridView
Event CellButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub CellContentClicked(sender As System.Object, e As DataGridViewCellEventArgs) Handles Me.CellContentClick
If TypeOf Me.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent CellButtonClick(Me, e)
End If
End Sub
End Class
Eso es. Nunca lo toques de nuevo. Asegúrese de que su DataGrid sea del tipo DataGridViewExtque debería funcionar exactamente igual que un DataGridView. Excepto que también generará un evento adicional que puedes manejar así:
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
