¿Por qué los prototipos de funciones de Perl 5 son malos?

En otra pregunta de Stack Overflow, Leon Timmermans afirmó:

Te aconsejo que no uses prototipos. Tienen sus usos, pero no en la mayoría de los casos y definitivamente no en este.

¿Por qué podría ser esto cierto (o no)? Casi siempre proporciono prototipos para mis funciones de Perl, y nunca antes había visto a nadie decir nada malo sobre su uso.

Los prototipos no son malos si se usan correctamente. La dificultad es que los prototipos de Perl no funcionan como la gente espera que lo hagan. Las personas con experiencia en otros lenguajes de programación tienden a esperar que los prototipos proporcionen un mecanismo para verificar que las llamadas a funciones sean correctas: es decir, que tengan el número y tipo de argumentos correctos. Los prototipos de Perl no son adecuados para esta tarea. Es el mal uso que es malo. Los prototipos de Perl tienen un propósito singular y muy diferente:

Los prototipos le permiten definir funciones que se comportan como funciones integradas.

• Los paréntesis son opcionales.
• El contexto se impone a los argumentos.

Por ejemplo, podría definir una función como esta:

sub mypush(\@@) { ... }

y llámalo como

mypush @array, 1, 2, 3;

sin necesidad de escribir el \para tomar una referencia a la matriz.

En pocas palabras, los prototipos le permiten crear su propio azúcar sintáctico. Por ejemplo, el marco de Moose los usa para emular una sintaxis OO más típica.

Esto es muy útil pero los prototipos son muy limitados:

• Deben ser visibles en tiempo de compilación.
• Se pueden omitir.
• La propagación del contexto a los argumentos puede provocar un comportamiento inesperado.
• Pueden dificultar la llamada de funciones utilizando cualquier otra forma que no sea la estrictamente prescrita.

Vea Prototipos en perlsub para todos los detalles sangrientos.

El problema es que los prototipos de funciones de Perl no hacen lo que la gente cree que hacen. Su propósito es permitirle escribir funciones que se analizarán como las funciones integradas de Perl.

En primer lugar, las llamadas a métodos ignoran por completo los prototipos. Si está haciendo programación OO, no importa qué prototipo tengan sus métodos. (Por lo que no deberían tener ningún prototipo).

En segundo lugar, los prototipos no se aplican estrictamente. Si llama a una subrutina con &function(...), el prototipo se ignora. Por lo que realmente no brindan ningún tipo de seguridad.

En tercer lugar, son acciones espeluznantes a distancia. (Especialmente el $prototipo, que hace que el parámetro correspondiente se evalúe en contexto escalar, en lugar del contexto de lista predeterminado).

En particular, dificultan el paso de parámetros desde matrices. Por ejemplo:

my @array = qw(a b c);

foo(@array);
foo(@array[0..1]);
foo($array[0], $array[1], $array[2]);

sub foo ($;$$) { print "@_\n" }

foo(@array);
foo(@array[0..1]);
foo($array[0], $array[1], $array[2]);

huellas dactilares:

a b c
a b
a b c
3
b
a b c

junto con 3 advertencias sobre main::foo() called too early to check prototype(si las advertencias están habilitadas). El problema es que una matriz (o porción de matriz) evaluada en contexto escalar devuelve la longitud de la matriz.

Si necesita escribir una función que actúe como una incorporada, use un prototipo. De lo contrario, no utilice prototipos.

Nota: Perl 6 tendrá prototipos completamente renovados y muy útiles. Esta respuesta se aplica solo a Perl 5.

Estoy de acuerdo con los dos carteles anteriores. En general, $debe evitarse su uso. Los prototipos son sólo es útil cuando se utiliza argumentos de bloque ( &), pegotes ( *), o prototipos de referencia ( \@, \$, \%, \*)

Algunas personas, al mirar un prototipo de subrutina de Perl, creen que significa algo que no significa:

sub some_sub ($$) { ... }

Para Perl, eso significa que el analizador espera dos argumentos. Es la forma de Perl de permitirle crear subrutinas que se comportan como integradas, todas las cuales saben qué esperar del código subsiguiente. Puedes leer sobre prototipos en perlsub

Sin leer la documentación, la gente adivina que los prototipos se refieren a la verificación de argumentos en tiempo de ejecución o algo similar que han visto en otros lenguajes. Como ocurre con la mayoría de las cosas que la gente adivina sobre Perl, resultan estar equivocadas.

Sin embargo, comenzando con Perl v5.20, Perl tiene una característica, experimental mientras escribo esto, que brinda algo más parecido a lo que los usuarios esperan y qué. Las firmas de subrutinas de Perl ejecutan el recuento de argumentos en tiempo, la asignación de variables y la configuración predeterminada:

use v5.20;
use feature qw(signatures);
no warnings qw(experimental::signatures);

animals( 'Buster', 'Nikki', 'Godzilla' );

sub animals ($cat, $dog, $lizard = 'Default reptile') { 
    say "The cat is $cat";
    say "The dog is $dog";
    say "The lizard is $lizard";
    }

Esta es la característica que probablemente desee si está considerando prototipos.