Haz que Vim muestre TODOS los espacios en blanco como un personaje

No puedo encontrar una manera de hacer que Vim muestre todos los espacios en blanco como un personaje. Todo lo que encontré fue sobre pestañas, espacios finales, etc.

Como otros han dicho, podrías usar

:set list

que, en combinación con

:set listchars=...

Mostrar caracteres invisibles.
Ahora, no hay una opción explícita que pueda usar para mostrar espacios en blanco, pero en los cuadros de lista, puede establecer un carácter para que se muestre para TODO PERO espacios en blanco. Por ejemplo, el mío se ve así

:set listchars=eol:$,tab:>-,trail:~,extends:>,precedes:<

entonces, ahora, después de usar

:set list

todo lo que no se muestra explícitamente como algo más, es entonces, realmente, un espacio en blanco simple.

Como de costumbre, para entender cómo listcharsfunciona, use la ayuda. Proporciona gran información sobre qué caracteres se pueden mostrar (como el espacio final, por ejemplo) y cómo hacerlo:

:help listchars

Puede ser útil agregarle un conmutador para que pueda ver los cambios a mitad de la edición fácilmente (fuente: VIM: set list! Como alternar en .vimrc ):

noremap <F5> :set list!<CR>
inoremap <F5> <C-o>:set list!<CR>
cnoremap <F5> <C-c>:set list!<CR>

¡A partir del parche 7.4.710 ahora puede configurar un personaje para que se muestre en lugar de espacio usando listchars!

:set listchars+=space:␣

Por lo tanto, para mostrar TODOS los espacios en blanco como caracteres, puede hacer lo siguiente:

:set listchars=eol:¬,tab:>·,trail:~,extends:>,precedes:<,space:␣
:set list

Discusión sobre la lista de correo: https://groups.google.com/forum/?fromgroups#!topic/vim_dev/pjmW6wOZW_Q

:set list para permitir.

:set nolist deshabilitar.

Creo que otras respuestas aquí son más completas, pero pensé en compartir un truco que suelo usar para diferenciar visualmente las pestañas y los espacios:

:syntax on
:set syntax=whitespace

Estas son reglas de resaltado de sintaxis para el lenguaje de programación de espacios en blanco: las pestañas se muestran en verde y los espacios en rojo. :)

Se puede combinar con :set listlo mencionado por muchas otras respuestas, aunque las pestañas se mostrarán como ^ I sin un resaltado verde, pero los espacios se mostrarán en rojo.

:set listmostrará todos los espacios en blanco como un personaje. Todo menos un espacio se verá diferente de su estado normal, lo que significa que si todavía ve un espacio antiguo simple, es realmente un espacio antiguo simple. :)

Si configura:

:highlight Search cterm=underline gui=underline ctermbg=none guibg=none ctermfg=none guifg=none

y luego realice una búsqueda de un espacio, cada carácter de espacio se mostrará como un carácter subrayado.

Puede usar este comando en una función práctica que alterna el "subrayado" de espacios.

set hls
let g:HLSpace = 1
let g:HLColorScheme = g:colors_name
function ToggleSpaceUnderscoring()
    if g:HLSpace
        highlight Search cterm=underline gui=underline ctermbg=none guibg=none ctermfg=none guifg=none
        let @/ = " "
    else
        highlight clear
        silent colorscheme "".g:HLColorScheme
        let @/ = ""
    endif
    let g:HLSpace = !g:HLSpace
endfunction

Asigne la función a una tecla de acceso directo con:

nmap <silent> <F3> <Esc>:call ToggleSpaceUnderscoring()<CR>

Nota: defina la función en vimrc después de que se haya configurado el esquema de colores.

Dependiendo de sus reglas de sintaxis para el búfer actual, algo como esto podría funcionar:

:syn match WhiteSpace / / containedin=ALL conceal cchar=Æ
:setl conceallevel=2 concealcursor=nv

Esto necesita un vim 7.3 con + función de ocultación

Actualización 24/10/2014 Para ampliar un poco sobre eso. Por supuesto, es posible definir algunos resaltados para los caracteres encerrados.

• Puede configurar cómo se ven los caracteres ocultos. Para resaltar, tendría que configurar al menos una vez el grupo de resaltado 'Ocultar' (consulte la ayuda en :h hl-ConcealEsto se puede hacer en su esquema de colores y luego no necesita volver a configurarlo nuevamente. Pero esto afecta a todos los caracteres ocultos (por ejemplo, si su el script de sintaxis oculta algunos elementos más, se mostrarán como caracteres de espacio en blanco).

  :hi Conceal ctermfg=7 ctermbg=NONE guifg=LightGrey guibg=NONE

• Parece existir una particularidad de que Vim no resaltará espacios, si el script de sintaxis usa la skipwhitepalabra clave. No habrá forma de evitarlo (tal vez esto se arregle, publiqué un parche )

• Parece que hay un parche flotando, que permitirá personalizar cómo se verán los espacios en el listmodo. El último en el momento de escribir parece ser este . (Esto significa que necesita construir su propio Vim para usar esto).
• El conceallevelyconcealcursor son ventana de opciones locales. Eso significa que pueden ser diferentes en diferentes ventanas (y posiblemente también se establecerán mediante complementos de tipo de archivo u otros scripts de complementos).
• Los grupos de resaltado de sintaxis deben ejecutarse cada vez que se vuelve a cargar un archivo de definición de sintaxis. Esto podría hacerse usando un BufWinEntero posiblemente también un Syntaxo inclusoFileType autocomando. (No he probado cuál funciona realmente).

Los dos últimos elementos significan que tendría que configurar algunos comandos automáticos que restablecen las reglas de sintaxis y las opciones de respuesta correspondientes. Para el primero, es posible que desee configurar el resaltado utilizando unColorScheme comando automático (para que los caracteres ocultos siempre se vean iguales, independientemente de lo que configure realmente un esquema de color). Para una solución completa, busque en la respuesta romana, que debería darle un comienzo. Si configura una función, puede configurar fácilmente un comando de alternar para activar o desactivar la visualización de resaltado especial.

Actualización 26/10/2014 Hice un complemento de esta pregunta.

Actualización 22/04/2015 Se ha incluido un parche en Vim que lo hace posible mediante la listopción. Simplemente configure set list listchars+=space:␣ Esto funciona a partir de Vim 7.4.711

yo uso esto

/\s
:set hlsearch

para resaltar espacios en blanco. Busca todos los espacios en blanco y luego habilita el resaltado para que salgan. Sin embargo, no imprime un carácter especial.

Si por espacios en blanco te refieres al carácter '', mi sugerencia sería solo una búsqueda / reemplazo. Como los demás han insinuado, set listcambia los caracteres que no se imprimen a un carácter visible que está configurado en listchars.

Para mostrar explícitamente espacios como algún otro personaje, algo similar a lo siguiente debería ser el truco:

:%s/ /█/g

Luego solo deshaga el cambio para volver de nuevo.

(Para obtener el █ Presioné esta secuencia de teclas exacta: :%s/ /CTRL-KFB/g)

Para resaltar espacios, solo búscalo:

/ <espacio>

Notas:

El siguiente código se basa en la respuesta de Christian Brabandt y parece hacer lo que quiere el OP:

function! Whitespace()
    if !exists('b:ws')
        highlight Conceal ctermbg=NONE ctermfg=240 cterm=NONE guibg=NONE guifg=#585858 gui=NONE
        highlight link Whitespace Conceal
        let b:ws = 1
    endif

    syntax clear Whitespace
    syntax match Whitespace / / containedin=ALL conceal cchar=·
    setlocal conceallevel=2 concealcursor=c
endfunction

augroup Whitespace
    autocmd!
    autocmd BufEnter,WinEnter * call Whitespace()
augroup END

Agregue esas líneas a su ~/.vimrce inicie una nueva sesión de Vim para ver cómo sucede la magia aún imperfecta .

Siéntase libre de editar los colores predeterminados y ocultar el carácter.

Advertencia: algo en el *FuncBodygrupo de sintaxis en varios idiomas impide que se muestre el punto medio. No sé (¿todavía?) Cómo hacer que esa solución sea más confiable.

Estaba frustrado con todas las otras respuestas a esta pregunta, porque ninguna de ellas resalta el carácter espacial de una manera útil. Mostrar espacios como caracteres sería particularmente útil para los idiomas con formato de espacios en blanco, donde mezclar pestañas y espacios es perjudicial.

Mi solución es mostrar pestañas y subrayar múltiples espacios. Toma prestado de la respuesta de mrucci y de este tutorial . Debido a que utiliza el resaltado de sintaxis, es persistente:

set list listchars=tab:\|\ 
highlight Whitespace cterm=underline gui=underline ctermbg=NONE guibg=NONE ctermfg=yellow guifg=yellow
autocmd ColorScheme * highlight Whitespace gui=underline ctermbg=NONE guibg=NONE ctermfg=yellow guifg=yellow
match Whitespace /  \+/

Con esto, las pestañas se muestran como |y los espacios como_ , lo que hace que sea muy fácil saber cuándo estoy mezclando estilos de código.

El único inconveniente que he encontrado es que este fragmento no ajusta el color de fondo para que coincida con el contexto (como en un comentario).

todas las respuestas anteriores intentan hacer espacios visibles desde vim. Si realmente insiste en tener espacios visibles como puntos, hay otro enfoque ...

Si no se puede hacer en vim, cambie su fuente por completo. Copié la fuente Ubuntu One Mono y la edité usando FontForge. Recuerde cambiar el nombre completo de la fuente, la familia, la familia preferida, la compatibilidad completa (en FontFoge está bajo los nombres TTF en la información de la fuente), para tenerla como una fuente separada. Simplemente edite el carácter de espacio para tener un punto en el medio y guarde la fuente en ~ / .fonts. Ahora puede usarlo para su gvim o la terminal completa ... Copié el "!" carácter, eliminó la línea y movió el punto al centro. Tomó un poco más de 5 minutos ...

Nota: cambiar el carácter de espacio (0x20) resulta en el inconveniente de tener puntos en toda la pantalla vim ... (pero separará los espacios de las pestañas ...)

No encontré exactamente lo que quería de las respuestas existentes. El siguiente código resaltará todos los espacios finales de color rojo brillante. Simplemente agregue lo siguiente a su.vimrc

highlight ExtraWhitespace ctermbg=red guibg=red
match ExtraWhitespace /\s\+$/
autocmd BufWinEnter * match ExtraWhitespace /\s\+$/
autocmd InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/
autocmd InsertLeave * match ExtraWhitespace /\s\+$/
autocmd BufWinLeave * call clearmatches()

:match CursorLine /\s\+/

evita el bit "tienes que buscar espacios para que aparezcan", pero un hecho no se puede configurar para hacer cosas que no sean de resaltado en los espacios. CursorLine puede ser cualquier grupo de resaltado y en el tema predeterminado es un subrayado simple.

Me gusta usar caracteres especiales para mostrar espacios en blanco, es más claro. Incluso un mapa para alternar es una característica clave, para una verificación rápida.

Puede encontrar estas características en un antiguo script vim no actualizado desde 2004:

vim-scripts/cream-showinvisibles@vim.org

Gracias al proyecto vim-scripts y vundle puedes revivir este complemento

vim-scripts / cream-showinvisibles @ github

Aún mejor, mis dos centavos en esto es agregar un acceso directo configurable (en lugar de predefinido F4)

así que agregue esto a ~ / .vimrc

Plugin 'albfan/cream-invisibles'

let g:creamInvisibleShortCut = "<F5>" "for my F4 goto next error

instalar el complemento en vim

:PluginInstall

y ahí vas

Para cubrir los caracteres de espacio en blanco Unicode:

set list
set listchars=tab:│\ ,nbsp:·
highlight StrangeWhitespace guibg=Red ctermbg=Red
" The list is from https://stackoverflow.com/a/37903645 (with `\t`, `\n`, ` `, `\xa0` removed):
call matchadd('StrangeWhitespace', '[\x0b\x0c\r\x1c\x1d\x1e\x1f\x85\u1680\u2000\u2001\u2002\u2003\u2004\u2005\u2006\u2007\u2008\u2009\u200a\u2028\u2029\u202f\u205f\u3000]')

El resultado:

• solo el espacio ordinal (U + 0020) se parece a un espacio (" ")
• la pestaña (U + 0009) se ve como " │ " (dos caracteres: una tubería larga y luego un espacio ordinal; son grises encolorscheme murphy )
• el espacio normal que no se rompe (U + 00A0) se ve como " ·" (un carácter; es gris colorscheme murphy)
• cualquier otro carácter de espacio en blanco parece rojo " "

Podrías usar

:set list

para ver realmente la estructura de una línea. Verá pestañas y nuevas líneas explícitamente. Cuando ves un espacio en blanco, es realmente un espacio en blanco.

resaltar búsqueda

:set hlsearch 

en .vimrc eso es

y busque pestañas espaciales y retornos de carro

/ \|\t\|\r

o buscar todos los espacios en blanco

/\s

de búsqueda de todos los caracteres que no sean espacios en blanco (no se muestran los espacios en blanco, por lo que puede ver los espacios en blanco entre palabras, pero no los caracteres en blanco)

/\S

para mostrar todos los caracteres de espacio en blanco al final de la línea

/\s$

Mantenga esos hacks en .vimrc como comentarios, así que en el shell, simplemente:

echo '
  " how-to see the non-visible while spaces
  " :set listchars=eol:¬,tab:>·,trail:~,extends:>,precedes:<,space:␣
  " set listchars=eol:$,tab:>-,trail:~,extends:>,precedes:<
  " :set list
  " but hei how-to unset the visible tabs ?!
  " :set nolist
  ' >> ~/.vimrc

:se list
:se nolist

:sees suficiente, :setno es necesario

También puede resaltar los espacios (reemplazando los espacios con un bloque):

:%s/ /█/g

(antes de escribir deshacerlo)

Agregar esto a mi .vimrc funciona para mí. Solo asegúrate de no tener nada más conflictivo.

autocmd VimEnter * :syn match space /\s/
autocmd VimEnter * :hi space ctermbg=lightgray ctermfg=black guibg=lightgray guifg=black