¿Cómo buscar una palabra árabe en texto sin sus signos diacríticos / acentos?

En árabe, como en algunos otros idiomas, existe lo que se llama diacríticos para mejorar la pronunciación. No existe una convención sobre cuántos signos diacríticos se deben escribir para una sola palabra. Algunos usan el mínimo (que prefiero) lo suficiente para desambiguar la pronunciación, mientras que otros los usan de manera superflua o solo con fines caligráficos estéticos. Por lo tanto, hay una amplia variación sobre qué y cuántos diacríticos están asociados con una palabra. Cuando lo hago isearch-forward/backwardpresionando C-s/r, surge un problema cuando lo escribo en el minibúfer de búsqueda sin signos diacríticos, no coincidirá con la misma palabra en el texto si tuviera signos diacríticos, lo que hace que la tarea de buscar esta palabra con sus signos diacríticos potenciales sea insatisfactoria.

¿Hay alguna manera de hacer que la búsqueda / búsqueda regular no sea consciente de los signos diacríticos? Espero que haya una respuesta que pueda extenderse para incluir regexp C-M-s/ry grepbuscar que uso con bastante frecuencia en helm-projectile para buscar una palabra en proyectos de látex de varios archivos.

Actualización
Sería bueno ver que Emacs en todas sus funciones de búsqueda realiza el paso de eliminación del texto (de acentos / signos diacríticos / lo que sea) antes de que coincida con el paso como un comportamiento predeterminado que puede ser desactivado por un prefijo a pedido no importa qué idioma tengamos a mano. Por lo general, cuando busco algo que no espero que el mejor editor (Emacs) falle en este recado solo por algunos signos diacríticos o acentos que rara vez se necesitan para realizar tareas de texto mundanas.

Aquí hay un comienzo difícil, basado en la lista de caracteres combinados en esta respuesta (y luego extendida). (Marcar esto como wiki de la comunidad - ¡edite y mejore esto!)

(defconst arabic-diacritics '(#x064b #x064c #x064d #x064e #x064f #x0650 #x0651 #x0652 #x0653 #x0654 #x0655 #x0670)
  "Unicode codepoints for Arabic combining characters.")
(defconst arabic-diacritics-regexp (regexp-opt (mapcar #'string arabic-diacritics)))

(defconst arabic-equivalents
  '(
    ;; "alef" is equivalent to "alef with hamza above" etc
    (#x0627 #x0623 #x0625 #x0622)))

;; (require 'cl-lib)    
;; (defun arabic-strip-diacritics (string)
;;   (cl-reduce (lambda (s c) (remove c s)) arabic-diacritics :initial-value string))

(defun arabic-search-without-diacritics (string)
  (interactive (list (read-string "Search for: " nil nil nil t)))
  (let ((regexp
         (apply #'concat
                (mapcar (lambda (c)
                          (let ((equivalents (assq c arabic-equivalents)))
                            (concat
                             (if equivalents
                                 (regexp-opt (mapcar #'string equivalents))
                               (regexp-quote (string c)))
                             arabic-diacritics-regexp "*")))
                        string))))
    (search-forward-regexp regexp)))

Entonces, si un búfer contiene "الْحَمْدُ لِلَّهِ رَبِّ الْعَالَمِينَ", y lo evalúo (arabic-search-without-diacritics "الحمد لله رب العالمين"), encuentra el texto. También funciona de forma interactiva, como M-x arabic-search-without-diacritics.

Enfoque alternativo:

Aquí hay un ejemplo de código completo que demuestra cómo Mnse pueden eliminar las marcas diacríticas y otras marcas ( propiedad) no espaciadoras de las cadenas normalizadas en las coincidencias de expresiones regulares . Funciona con los ejemplos dados y la OMI es el enfoque correcto.

(defun kill-marks (string)
  (concat (loop for c across string
                when (not (eq 'Mn (get-char-code-property c 'general-category)))
                collect c)))

(let* ((original1 "your Arabic string here")
      (normalized1 (ucs-normalize-NFKD-string original1))
      (original2 "your other Arabic string here")
      (normalized2 (ucs-normalize-NFKD-string original2)))
  (equal
   (replace-regexp-in-string "." 'kill-marks normalized1)
   (replace-regexp-in-string "." 'kill-marks normalized2)))