¿Cómo puedo ejecutar una macro de teclado en buffers seleccionados de Ibuffer o archivos seleccionados de dired?

Si tengo que hacer una refactorización de nombres de variables, uso ag y múltiples cursores .

Pero cuando tengo que eliminar / agregar / mover un bloque de código, uso macros de teclado. Pero necesito cambiar a cada búfer e iniciar la ejecución de esa macro manualmente.

¿Hay alguna manera de simplemente seleccionar los búferes abiertos de Ibuffer (o archivos de dired) y ejecutar la última macro de teclado grabada en todos ellos?

Modificar buffers Ibuffer seleccionados

Después de grabar la macro del teclado, cambie a Ibuffer y,

• Marque los tampones deseados usando m
• Hit W- Eval mientras visualiza el búfer (la evaluación simple ENO funciona para llamadas de macro)
• (kmacro-end-or-call-macro 1)

Simplemente incluye el cambio de búfer en la macro. No está restringido a un solo búfer: ¡una macro de teclado puede hacer cualquier cosa que pueda hacer!

Respondí esta misma pregunta el otro día en SO, así que consulte la macro de teclado de archivos cruzados de emacs .

Aquí hay un comando que hace que la ejecución de comandos, macros y la evaluación de expresiones Lisp en múltiples archivos sea obvia. Tenga en cuenta que el argumento prefijo permite ejecutar una macro para cada archivo hasta que se produce un error. Ya publiqué esto en el superusuario, pero funciona tan bien que pensé que las personas que visiten esta página también podrían encontrarlo útil. Me gusta vincular esto a 'E' en dired.

Actualización: la versión anterior de esta función solo admitía macros. El actualizado es más simple y más potente, lo que permite ejecutar comandos arbitrarios (por secuencia de teclas o nombre), así como expresiones Lisp. Ahora también es cuidadoso registrar cualquier error en el búfer de mensajes .

;; Inspired by M-x edit-kbd-macro and https://superuser.com/q/176627.
(defun my-dired-do-execute (keys &optional arg)
  "Execute a command in all marked files.
If an error occurs, execution in other files is not affected.
(Notably, this allows to run keyboard macros until there is an error.)

At the prompt, type any bound key sequence, or `\\[execute-extended-command]'
to choose a command by its name, or `\\[eval-expression]' to enter a Lisp expression.

The prefix ARG, if given, is passed on to the chosen command.
"
  (interactive
   (list (read-key-sequence (substitute-command-keys "Key sequence to execute, \
or \\[eval-expression], or \\[execute-extended-command]: "))
         current-prefix-arg))
  (when keys
    (let ((cmd (if (arrayp keys) (key-binding keys) keys))
          exp)
      (cond ((eq cmd 'execute-extended-command)
             (setq cmd (read-command "Name of command to execute: "))
             (if (string-equal cmd "")
                 (error "No command name given")))
            ((eq cmd 'eval-expression)
             (setq exp (read--expression "Eval in selected files: "))
             (setq cmd nil))
            ((null cmd)
             (error "Key sequence %s is not defined" (key-description keys))))
      (mapc (lambda (filename)
              (save-selected-window
                (find-file-other-window filename)
                (setq current-prefix-arg arg)
                (condition-case-unless-debug err
                    (if cmd
                        (call-interactively cmd)
                      (message "Result in file %s:" filename)
                      (eval-expression exp))
                  (error (message "In file %s: %S" filename err)))))
            (dired-get-marked-files)))))

Modificar archivos seleccionados en dired

La siguiente solución necesita la instalación del dired+paquete, que está disponible en Melpa.

1. En primer lugar, convierta su macro de teclado en una función elisp. Aquí hay un emacs relacionado.SE QnA (¿Cómo guardar una macro de teclado como una función Lisp?).

   Es aún más rápido si sabe cómo desea modificar todos los archivos utilizando una función elisp directamente. Supongamos que desea agregar "- * - mode: org - * -" al comienzo de todos los archivos seleccionados en dired. ¹

   En ese caso, funcionaría la siguiente función elisp en cada uno de los archivos seleccionados.

   (defun my/set-org-mode ()
     (goto-char (point-min))
     (insert "-*- mode: org -*-\n"))

   Así que solo evalúa la función anterior por ahora; se utilizará en un paso posterior a continuación.

2. Haga M-x diredy abra el directorio que contiene los archivos en los que desea ejecutar la función anterior.
3. Marque todos esos archivos usando la mclave (vinculada a dired-markin dired).
4. * paso mágico * : C-u @selecciona y selecciona el nombre de la función que evaluaste en el Paso 1 ( my/set-org-mode). @está vinculado a lo diredp-do-apply-functionque se define en dired+.el.
5. ¡Auge! La línea "- * - mode: org - * -" se agregará en la parte superior de todos los archivos marcados. Pero las cosas aún no se guardan. Puede revisar todo lo que cambió si lo desea y luego presionar C-x s !para guardar todos los archivos modificados de una vez.

¹ : inspirado en esta pregunta en reddit .