¿Cómo obtener los datos en bruto para una agenda en modo organización sin una vista de agenda?

P: ¿Cómo puedo org-modedevolver los datos en bruto para una vista de agenda sin crear realmente una vista de agenda?

Me gustaría acceder a mi agenda para un día arbitrario. Sin embargo, no quiero crear una vista de agenda per se. En cambio, quiero org-moderecopilar y clasificar todos los elementos que irían a la vista de agenda para ese día y devolverlos (idealmente en una lista) para su posterior inspección y manipulación.

Supuse que ese org-agenda-listsería el lugar para comenzar. Sin embargo, esa función es una bestia enredada y parece entremezclar los procesos de recopilación, clasificación y visualización. Como tal, supongo (¿espero?) Que simplemente me he perdido la función relevante en algún lugar que proporciona la funcionalidad que busco.

El siguiente es un ejemplo de cómo condensada para extraer los datos que entra en un *Org Agenda*tampón cuando normalmente utilizando la función org-agenda-list, con org-agenda-entry-typestal como :deadline, :scheduled, :timestamp, sexp, :deadline*, y :scheduled*. El rango de fechas - beginy end- debe estar en un formato de lista gregoriano - por ejemplo, '(6 1 2015). Las opciones personalizables de let-bound son org-agenda-prefix-formaty org-agenda-entry-types. La función devuelve un resultado en el formato de una lista.

(require 'calendar)
(require 'org)
(require 'org-agenda)
(require 'cl)

;; Portions of following code were extracted from:
;;   https://github.com/kiwanami/emacs-calfw written by Masashi Sakurai
;; Said code has been modified by @lawlist hereinbelow.
;;
(defun org-get-entries-fn (begin end)
"Return org schedule items between BEGIN and END.
USAGE:  (org-get-entries-fn '(6 1 2015) '(12 31 2020))"
  (unless
      (and
        (calendar-date-is-valid-p begin)
        (calendar-date-is-valid-p end))
    (let ((debug-on-quit nil))
      (signal 'quit '("One or both of your Gregorian dates are invalid."))))
  (let* (
      result
      (org-agenda-buffer nil) ;; prevent error from `org-compile-prefix-format'
      ;; The variable `org-agenda-only-exact-dates' is apparently not operational.
      (org-scheduled-past-days 0) ;; avoid duplicate entries for overdue items
      (org-agenda-prefix-format "• ")
      (org-agenda-entry-types '(:scheduled))
      (date-after
        (lambda (date num)
          "Return the date after NUM days from DATE."
          (calendar-gregorian-from-absolute
           (+ (calendar-absolute-from-gregorian date) num))))
      (enumerate-days
        (lambda (begin end)
          "Enumerate date objects between BEGIN and END."
          (when (> (calendar-absolute-from-gregorian begin)
                   (calendar-absolute-from-gregorian end))
            (error "Invalid period : %S - %S" begin end))
          (let ((d begin) ret (cont t))
            (while cont
              (push (copy-sequence d) ret)
              (setq cont (not (equal d end)))
              (setq d (funcall date-after d 1)))
            (nreverse ret)))) )
    (org-compile-prefix-format nil)
    (setq result
      (loop for date in (funcall enumerate-days begin end) append
        (loop for file in (org-agenda-files nil 'ifmode) append
          (progn
            (org-check-agenda-file file)
            (apply 'org-agenda-get-day-entries file date org-agenda-entry-types)))))
    result))