Cambiar la orientación dividida de la ventana, la forma más rápida

Digamos que tiene dos buffers abiertos así:

------------------------------------
            |                      |
  buffer 1  |        buffer 2      |       
            |                      |
------------------------------------

¿Cuál es la forma más rápida de cambiar los búferes para obtener esto?

------------------------------------
           buffer 1                |
                                   |
------------------------------------
            buffer 2               |
                                   |
------------------------------------

buffers window

— Edgar Aroutiounian
fuente

stackoverflow.com/a/10546694 . biblioteca de transposición de cuadros. Descargo de responsabilidad: no lo he probado.

— Faheem Mitha

Hay una página wiki sobre este tema: emacswiki.org/emacs/ToggleWindowSplit

— Chris Martin

Ver emacs.stackexchange.com/q/5371 ; en particular una respuesta menciona transpose-frameen MELPA.

— TooTone

Aquí hay un defun que haría lo que estás buscando:

(defun toggle-window-split ()
  (interactive)
  (if (= (count-windows) 2)
      (let* ((this-win-buffer (window-buffer))
             (next-win-buffer (window-buffer (next-window)))
             (this-win-edges (window-edges (selected-window)))
             (next-win-edges (window-edges (next-window)))
             (this-win-2nd (not (and (<= (car this-win-edges)
                                         (car next-win-edges))
                                     (<= (cadr this-win-edges)
                                         (cadr next-win-edges)))))
             (splitter
              (if (= (car this-win-edges)
                     (car (window-edges (next-window))))
                  'split-window-horizontally
                'split-window-vertically)))
        (delete-other-windows)
        (let ((first-win (selected-window)))
          (funcall splitter)
          (if this-win-2nd (other-window 1))
          (set-window-buffer (selected-window) this-win-buffer)
          (set-window-buffer (next-window) next-win-buffer)
          (select-window first-win)
          (if this-win-2nd (other-window 1))))))

( Copiado descaradamente de Magnars .emacs.d )

Además, si lo vuelve a llamar, volverá a dividir sus ventanas en la orientación vertical original.

— waymondo
fuente

Sería bueno si esto pudiera preservar la relación de tamaño relativo de las dos ventanas. A menudo mantengo una ventana "corta" desigual en la parte inferior, y al cambiar de un lado a otro, sería útil preservar este tamaño relativo. Aunque una ventana vertical estrecha probablemente sea menos útil.

— b4hand

No puedo decirte cuántas veces uso esto. Muy útil

— Edgar Aroutiounian