Inserción automática de los últimos valores de subíndice / superíndice utilizados en fórmulas matemáticas

Yo uso AUCTeX para textos matemáticos tipográficos. A menudo tengo que escribir ecuaciones con sumas, integrales, etc. que tienen todos los mismos subíndices o superíndices. Me gustaría autocompletar el subíndice / superíndice actual con el valor que tenía antes. Ejemplo:

\sum_{i=1}^{\infty} a_i = \sum…

Cuando presiono _en la ecuación anterior, Emacs debería escribir _{i=1}. Opcional, sería bueno si el segundo superíndice también se completara.

¿Cómo se puede realizar esto?

Añadir a su archivo de inicio:

(defvar mg-TeX-insert-subscript-history nil)
(defvar mg-TeX-insert-superscript-history nil)

(defun TeX-insert-sub-or-superscript (arg)
  "Insert typed key ARG times and possibly a pair of braces.
Brace insertion is only done if point is in a math construct and
`TeX-electric-sub-and-superscript' has a non-nil value."
  (interactive "*p")
  (self-insert-command arg)
  (when (and TeX-electric-sub-and-superscript (texmathp))
    (let* ((history (cond
             ((equal last-input-event ?_)
              'mg-TeX-insert-subscript-history)
             ((equal last-input-event ?^)
              'mg-TeX-insert-superscript-history)))
       (content (read-string "Content: " (car (symbol-value history)) history)))
      (insert (concat TeX-grop content TeX-grcl))
      (if (zerop (length content))
      (backward-char)))))

Asegúrese de que TeX-electric-sub-and-superscriptesté configurado en no nulo.

Aquí hay una versión que inserta de forma no interactiva el último sub / súper script que se produce para el token en el punto:

(defun my/electric-sub-super-script (arg)
  "Insert typed character ARG times and possibly a sub/super-script.
Sub/super-script insertion is done only in a (La)TeX math mode region.
The inserted sub/super-script is copied from the last occurence of a
sub/superscript for the token at point."
  (interactive "p")
  (self-insert-command arg)
  (when (texmathp)
    (insert
     (save-excursion
       (let ((current-token (let ((end (point)))
                              (backward-sexp 1)
                              (buffer-substring-no-properties (point) end))))
         (if (search-backward current-token nil t)
             (progn
               (search-forward current-token)
               (let ((begin (point)))
                 (forward-sexp 1)
                 (buffer-substring-no-properties begin (point))))
           ""))))))

(define-key TeX-mode-map (kbd "_") #'my/electric-sub-super-script)
(define-key TeX-mode-map (kbd "^") #'my/electric-sub-super-script)

Tomando el ejemplo en la pregunta, a continuación se muestra la secuencia de estados de búfer obtenidos al comenzar con la primera línea y escribir _^SPCa_:

\sum_{i=1}^{\infty} a_i = \sum▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty}▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty} a▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty} a_i▮