¿Cómo atrapar y manejar solo excepciones específicas de Oracle?

De esto y de esto , supongo, que no hay excepciones de sistema con nombre predefinidas para ORA-00955.

¿Cómo puedo reescribir lo siguiente para detectar solo el error ORA-00955?

begin
      EXECUTE IMMEDIATE 'CREATE SEQUENCE S_TEST START WITH 1 INCREMENT BY 1';
exception when OTHERS then
    Null;
end;

Por cierto, ¿hay alguna sintaxis para detectar errores simplemente proporcionando los códigos de error?

Tienes dos opciones:

Consulte la excepción directamente por número:

BEGIN
    EXECUTE IMMEDIATE 'CREATE SEQUENCE S_TEST START WITH 1 INCREMENT BY 1';
EXCEPTION
    WHEN OTHERS THEN
      IF SQLCODE = -955 THEN
        NULL; -- suppresses ORA-00955 exception
      ELSE
         RAISE;
      END IF;
END; 

Otra opción es usar la EXCEPTION_INITdirectiva Pragma para vincular un número de error de Oracle conocido a la excepción definida por el usuario;

DECLARE
   name_in_use exception; --declare a user defined exception
   pragma exception_init( name_in_use, -955 ); --bind the error code to the above 
BEGIN
    EXECUTE IMMEDIATE 'CREATE SEQUENCE S_TEST START WITH 1 INCREMENT BY 1';
EXCEPTION
    when name_in_use then
       null; --suppress ORA-00955 exception
END; 

Por cierto, ¿hay alguna sintaxis para detectar errores simplemente proporcionando los códigos de error?

Sí, lo he demostrado en el primer ejemplo.

Lecturas adicionales para variaciones sobre esto:

• Documentación de referencia de Oracle sobre manejo de excepciones PL / SQL

Similar a lo que Sathya ya ha sugerido, pero me gusta evitarlo por when otherscompleto si es posible: una excepción no controlada suele ser el resultado correcto para excepciones que no está manejando específicamente:

create sequence foo;
/*
sequence FOO created.
*/
declare
  name_is_already_used_955 exception;
  pragma exception_init(name_is_already_used_955,-955);
begin
  execute immediate 'create sequence foo';
exception when name_is_already_used_955 then null;
end;
/
/*
anonymous block completed
*/