Generar script para automatizar el cambio de nombre de las restricciones predeterminadas

Antecedentes: algunas de nuestras restricciones de columna predeterminadas se generaron sin nombres explícitos, por lo que obtenemos nombres divertidos que varían de un servidor a otro como: DF__User__TimeZoneIn__5C4D869D

Preferiría que todos sean manejables con un nombre consistente como DF_Users_TimeZoneInfopara que podamos asegurarnos de que existan las restricciones apropiadas en las tablas de destino futuras (como en la comparación de RedGate, o incluso solo visualmente)

Tengo un script que funciona principalmente para lo que quiero:

select 'sp_rename N''[' + s.name + '].[' + d.name + ']'', 
   N''[DF_' + t.name + '_' + c.name + ']'', ''OBJECT'';'
from sys.tables t
    join
    sys.default_constraints d
        on d.parent_object_id = t.object_id
    join
    sys.columns c
        on c.object_id = t.object_id
        and c.column_id = d.parent_column_id
    join sys.schemas s
        on t.schema_id = s.schema_id
WHERE d.NAME like 'DF[_][_]%'

Pero esto solo me da un conjunto de resultados, y no algo que realmente pueda pasar a un ejecutivo o lo que sea.

¿Cómo puedo hacer esto para poder ejecutar esos sp_renamescripts sin tener que recurrir a copiar todos los elementos devueltos y pegarlos en una nueva ventana de consulta y ejecutarlos nuevamente? Intento guardar tantas pulsaciones de teclas como sea posible para poder corregir esto en muchos entornos.

Ok, un par de cosas

1. siempre se usa EXECal ejecutar procedimientos almacenados; la taquigrafía sin EXECsolo funciona cuando es la primera instrucción del lote (y ese no será el caso aquí).
2. siempre use terminadores de punto y coma ; en este caso, son útiles en lugar de retornos de carro bonitos y sangría, pero siempre es aconsejable tenerlos.
3. siempre use en QUOTENAME()lugar de aplicar corchetes manualmente usted mismo. En este caso, probablemente esté a salvo, pero hay casos en los que el enfoque manual se romperá.

4. puede probar la PRINTsalida, pero no necesariamente estará completa si su comando total es> 8k (consulte este consejo para conocer algunos enfoques alternativos ).

   DECLARE @sql nvarchar(max) = N'';
   
   SELECT @sql += N'EXEC sys.sp_rename N''' 
       + QUOTENAME(s.name) + '.' + QUOTENAME(d.name) 
       + ''', N''DF_' + t.name + '_' + c.name + ''', ''OBJECT'';'
     FROM sys.tables AS t
     INNER JOIN sys.default_constraints AS d
        ON d.parent_object_id = t.object_id
     INNER JOIN sys.columns AS c
        ON c.object_id = t.object_id
       AND c.column_id = d.parent_column_id
     INNER JOIN sys.schemas AS s
        ON t.schema_id = s.schema_id
     WHERE d.NAME LIKE N'DF[_][_]%';
   
   PRINT @sql;
   -- EXEC sys.sp_executesql @sql;

Según su pregunta ... que ha eliminado "automatice el mismo script en algunas de las bases de datos de la instancia"

A continuación se muestra el código que lo ayudará.

set nocount on
DECLARE @table TABLE 
  ( 
     dbname VARCHAR(30) 
  ) 

INSERT INTO @table 
            (dbname) 
VALUES      ( 'dev_construct1' ), 
            ('dev_construct2'), 
            ('dev_construct3' ); 

DECLARE @sql NVARCHAR(max) = N''; 
DECLARE @dbname VARCHAR(30) 

/*  
Added by Kin : While loop and an extra @dbname variable 
*/ 
SELECT @dbname = Min(dbname) 
FROM   @table 

WHILE @dbname IS NOT NULL 
  BEGIN 
      SELECT @sql = N'USE ' + tt.dbname + Char(10) + N' GO;'
      FROM   @table tt 
      WHERE  @dbname = dbname 

      SELECT @sql += Char(10) + N'EXEC sp_rename N''' 
                     + Quotename(s.name) + '.' + Quotename(d.name) 
                     + ''', N''DF_' + t.name + '_' + c.name 
                     + ''', ''OBJECT'';' 
      FROM   sys.tables AS t 
             JOIN sys.default_constraints d 
               ON d.parent_object_id = t.object_id 
             JOIN sys.columns c 
               ON c.object_id = t.object_id 
                  AND c.column_id = d.parent_column_id 
             JOIN sys.schemas s 
               ON t.schema_id = s.schema_id 
             JOIN @table tt 
               ON tt.dbname = tt.dbname 
      WHERE  d.name LIKE 'DF[_][_]%'; 

      PRINT @sql 

      SELECT @dbname = Min(dbname) 
      FROM   @table 
      WHERE  dbname > @dbname 
  END 
-- EXEC sp_executesql @sql;