Al abrir un archivo DMG, ¿cómo hago para que se abra frente a las ventanas?

Cada vez que descargo un .dmgarchivo y luego lo abro (generalmente desde la barra de descarga en Chrome), se abre en segundo plano. ¿Hay alguna forma de que se abra frente a mi ventana?

Editar

Para aclarar: quiero que la ventana DMG aparezca como la ventana activa.

Creé un script de acción de carpeta en Applescript, que podría hacer exactamente lo que quieres. Cópielo y péguelo en un nuevo Applescript, y guárdelo como una Aplicación (¡sin un diálogo de inicio!) En "/ Library / Scripts / Folder Action Scripts /". Luego puede adjuntarlo a cualquier carpeta (muy probablemente su ~ / Descargas / carpeta) haciendo clic derecho en la carpeta y seleccionando "configurar acciones de carpeta" en el menú desplegable de servicios. Active las acciones de la carpeta y deje que el script vea la carpeta.

Lo que básicamente hace el script es reaccionar a los elementos que se han caído en la carpeta a la que está adjunto y si el elemento que se ha caído es de tipo: "Imagen" adjunta la imagen como un volumen a través de la herramienta de línea de comandos "hdiutil".

Puede configurar su comportamiento configurando las propiedades openWindow y makeFrontmost en el Script; Esto también se puede hacer haciendo doble clic en el Script después de haberlo guardado como una aplicación; luego, en dos diálogos, se le preguntará cuál debería ser su comportamiento estándar.

Espero que esto ayude,

Asmus

 property openWindow : true
 property makeFrontmost : true

 on run

    display dialog "Do you want to bring the Finder to the front after new items are added?" buttons {"Don't Activate", "Activate"} default button 2
    if the button returned of the result is "Don't Activate" then
        set makeFrontmost to false
    else
        set makeFrontmost to true
    end if


    display dialog "Open Folder after adding new files?" buttons {"Don't Open", "Open"} default button 2
    if the button returned of the result is "Don't Open" then
        set openWindow to false
    else
        set openWindow to true
    end if


 end run

 on adding folder items to thisFolder after receiving addedItems

    repeat with i from 1 to number of items in addedItems
        set itemKind to the kind of (info for item i of addedItems) as string

        if itemKind is "Disk Image" then
            set itemPath to (quoted form of POSIX path of item i of addedItems)
            try
                showImage(itemPath)
            end try
        end if

    end repeat

 end adding folder items to


 on showImage(itemPath)

    set volumeMountpointInfo to do shell script "/usr/bin/hdiutil  attach " & itemPath & " | grep Volumes"


    if (openWindow is true) then
        if (makeFrontmost is true) then
            tell application "Finder" to activate
        end if

       set currentDelim to text item delimiters
       set text item delimiters to tab

       set volumeMountpoint to POSIX file (text item 3 of volumeMountpointInfo)

       set text item delimiters to currentDelim

       tell application "Finder" to open folder volumeMountpoint

    end if

 end showImage

====

segundo Applescript para determinar el tipo de archivo caído en una carpeta

On adding folder items to thisFolder after receiving addedItems
repeat with i from 1 to number of items in addedItems
    set itemKind to the kind of (info for item i of addedItems) as string
    display dialog itemKind
end repeat
end adding folder items to

La edición debe ser "Imagen de disco" en lugar de "Imagen"

Por lo que puedo decir, OS X solo mostrará automáticamente el contenido de una imagen de disco si es de solo lectura. Esto se indica con un lápiz con una barra a través de él en la parte inferior izquierda de la ventana del Finder cuando se visualiza el contenido de la imagen.

Si desea cambiar una imagen de disco para que lo haga, puede hacer que una imagen de disco existente sea de solo lectura utilizando la Utilidad de Discos. Desafortunadamente, esto no cambiará el comportamiento de las imágenes producidas incorrectamente que puede descargar de Internet.

1. Monte la imagen de disco que desea abrir automáticamente.
2. Abra la Utilidad de Disco buscándola con Spotlight.
3. Seleccione el icono "Nueva imagen" en la barra de herramientas.
4. Asigne un nombre al archivo y seleccione "solo lectura" en "Formato de imagen".
5. Clic en Guardar." Cuando monte esta nueva imagen, se abrirá automáticamente una ventana del Finder.

Esto probablemente tampoco responde la pregunta lo suficiente, pero ...

Si presiona comando y hace clic en el elemento en la barra de descarga, muestra el elemento en el buscador. En ese punto, simplemente presionando el comando-O (o haciendo doble clic en el archivo dmg) lo montará y lo abrirá en una nueva ventana en primer plano.