¿Cómo decirle a Mensajes "No estoy en casa"?

Dejo mi Mac funcionando las 24 horas, los 7 días de la semana, pero no siempre estoy sentado allí.

¿Hay alguna manera de decirle a la Mac, o mensajes específicamente, si mi teléfono no está en la subred wifi local, no tome mensajes, déjelos para que mi iPhone los recoja.

Actualmente, si por alguna razón estoy fuera del alcance de iMessage pero soy capaz de recibir SMS, los mensajes nunca llegan a mi teléfono y no son retransmitidos después de fallar por el remitente, porque el sistema considera que entregarlos a mi Mac es prueba suficiente Los vi.

La pérdida de trabajos que me ofrecieron hace 6 horas, solo porque estaba afk, no es un espectáculo feliz para volver a casa.

Una opción: cerrar sesión en Messages en la Mac cada vez que salgo de casa ...
... nunca lo recordaré.
Editar: Cerrar la sesión de iMessage en Mac es considerablemente más problemático de lo que vale. Genera media docena de mensajes y correos electrónicos para cada dispositivo y cuenta ...

En primer lugar, necesita homebrew instalado en su sistema. Si no lo ha hecho, visite http://brew.sh para obtener instrucciones, o hágamelo saber e intentaré guiarlo.

Entonces necesitas instalar arp-scan. Para hacerlo, abra una Terminal y escriba brew install arp-scan.

Próximo paso. Guarde el siguiente script, llamé check-iphone-available.scpt, pero puede cambiar el nombre si lo desea.

set IPHONE to do shell script "if /usr/local/bin/arp-scan -l | grep your-iphone-mac; then echo 1; else echo 0; fi" user name "your-username" password "your-password" with administrator privileges
tell application "System Events"
    tell process "Messages"
        tell menu bar 1
            tell menu bar item "Messages"
                tell menu "Messages"
                    tell menu item "My Status"
                        tell menu "My Status"
                            if IPHONE is not equal to "0" then
                                click menu item "Available"
                            else
                                click menu item "Away"
                            end if
                        end tell
                    end tell
                end tell
             end tell
        end tell
    end tell
end tell

Reemplazar your-username, your-passwordy your-iphone-mac.

• your-username debe ser un usuario administrador que pueda sudo en su computadora.
• your-password contraseña para ese usuario.
• your-iphone-macse puede obtener en su iphone, vaya a Settings-> General-> Abouty copie Wi-Fi Address.

Dar permisos: chmod 775 check-iphone-available.scpt.

El script ejecuta como administrador el comando arp-scan. Este comando envía paquetes ARP a los hosts en la red local y muestra las respuestas que se reciben. El grepcomando busca tu iphone en la respuesta recibida por arp-scan. Si se encuentra el iPhone, a continuación, volver 1, de lo contrario, devuelve 0. En 1, la secuencia de comandos Haz clic en el elemento de menú disponible en mensajes, en 0, en la misma distancia (se puede cambiar por Offline, On the phone, etc).

Entonces, hagámoslo automáticamente.

Vaya a la carpeta /Users/your-username/Library/LaunchAgentsy guarde allí el siguiente archivo plist. Lo nombré com.username.checkiphone.plist, pero nuevamente, siéntase libre de cambiarlo.

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<dict>
  <key>Label</key>
  <string>com.your-username.checkiphone</string>

  <key>ProgramArguments</key>
  <array>
    <string>/usr/bin/osascript</string>
    <string>/Users/your-username/bin/check-iphone-available.scpt</string>
  </array>

  <key>Nice</key>
  <integer>1</integer>

  <key>StartInterval</key>
  <integer>60</integer>

  <key>RunAtLoad</key>
  <true/>

  <key>StandardErrorPath</key>
  <string>/tmp/com.your-username.checkiphone-available.err</string>

  <key>StandardOutPath</key>
  <string>/tmp/com.your-username.checkiphone-available.out</string>
</dict>
</plist>

El archivo se explica por sí mismo. Lanzaremos el comando /usr/bin/osascript /Users/your-username/bin/check-iphone-available.scptcada 60 segundos, lo lanzaremos en la carga, guardaremos errores /tmp/com.username.checkiphone-available.erre iniciaremos sesión /tmp/com.username.checkiphone-available.out.

Nuevamente, reemplace your-usernameapropiadamente.

Último paso, dile al demonio launchd de Mac que lo cargue.

launchctl load com.your-username.checkiphone.plist

Para detener el guión, simplemente reemplace la palabra loadcon unloaden la oración anterior. Cuando reinicie su computadora, el script se cargará nuevamente. Para evitarlo, muévalo a otra carpeta.

Segunda solución Esta vez basado en bluetooth.

Descargar Bluetooth Proximity Tasker . Lo siento amigo, pero cuesta $ 2.99.

Ejecute cualquier AppleScript cuando un dispositivo Bluetooth emparejado entre y salga del alcance. Ajuste el rango usando la intensidad de la señal.

Seleccione su dispositivo BT y pegue este script en In Range Applescript:

tell application "System Events"
    tell process "Messages"
        tell menu bar 1
            tell menu bar item "Messages"
                tell menu "Messages"
                    tell menu item "My Status"
                        tell menu "My Status"
                                click menu item "Available"
                        end tell
                    end tell
                end tell
             end tell
        end tell
    end tell
end tell

Reemplace Availablecon Awayen el script y pegue Out Of Range Applescript.

Tercera solución Para que esto funcione, debe tener una cuenta en ifttt.com (y la aplicación ifttt para iPhone ) y también una cuenta de Dropbox .

Creo un par de recetas en ifttt, si estoy en casa creo un archivo en Dropbox y si salgo de casa creo un archivo en Dropbox . Tendrás que modificarlo con tu dirección.

• El primero crea un archivo llamado AtHomeen el directorio IFTTT/iOSen su carpeta de Dropbox.
• En segundo lugar, cree un archivo llamado Outen el directorio IFTTT/iOSen su carpeta de Dropbox.

En ambas recetas cuando su iPhone ingrese o salga y el área que definió (su casa), cree uno u otro archivo en su Dropbox.

Entonces esto es más fácil de agregar para ambos archivos con este applecritp. El script busca archivos creados y, si existe, cambie iMessages en consecuencia y luego elimine el archivo. Si ninguno de esos archivos existe, no hará nada, por lo tanto, iMessages mantendrá el estado hasta que se cree el siguiente archivo.

on FileExists(theFile) -- (String) as Boolean
    tell application "System Events"
        if exists file theFile then
            return true
        else
            return false
        end if
    end tell
end FileExists

set IPHONE to FileExists("/Users/username/Dropbox/IFTTT/iOS/AtHome")
if IPHONE then
    set CHANGESTATUS to true
    do shell script "rm -rf /Users/username/Dropbox/IFTTT/iOS/AtHome"
else
    set CHANGESTATUS to false
end if

if CHANGESTATUS is not equal to true then
    set IPHONE to FileExists("/Users/username/Dropbox/IFTTT/iOS/Out")
    if IPHONE then
        set CHANGESTATUS to true
        set IPHONE to false
        do shell script "rm -rf /Users/username/Dropbox/IFTTT/iOS/Out"
    end if
end if

if CHANGESTATUS then
    tell application "System Events"
        tell process "Messages"
            tell menu bar 1
                tell menu bar item "Messages"
                    tell menu "Messages"
                        tell menu item "My Status"
                            tell menu "My Status"
                                if IPHONE then
                                    click menu item "Available"
                                else
                                    click menu item "Offline"
                                end if
                            end tell
                        end tell
                    end tell
                end tell
            end tell
        end tell
    end tell
end if

Debes cambiar /Users/username/Dropbox/IFTTT/iOS/para señalar tu camino real.

Después de esto, reemplace el guión de mi primera respuesta con esto, ¡y debería funcionar!