Principalmente uso esta función:
cf() {
cd "$(osascript -e 'tell app "Finder" to POSIX path of (insertion location as alias)')"
}
También puede asignar un acceso directo a un script como los que se muestran a continuación.
Reutilice una pestaña existente o cree una nueva ventana (Terminal):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if (exists window 1) and not busy of window 1 then
do script "cd " & quoted form of p in window 1
else
do script "cd " & quoted form of p
end if
activate
end tell
Reutilice una pestaña existente o cree una nueva pestaña (Terminal):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if not (exists window 1) then reopen
activate
if busy of window 1 then
tell application "System Events" to keystroke "t" using command down
end if
do script "cd " & quoted form of p in window 1
end tell
Siempre cree una nueva pestaña (iTerm 2):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "iTerm"
if exists current terminal then
current terminal
else
make new terminal
end if
tell (launch session "Default") of result to write text "cd " & quoted form of p
activate
end tell
Los dos primeros scripts tienen algunas ventajas en comparación con los servicios agregados en 10.7:
- A partir de 10.9, hay un error en el que los servicios que reciben carpetas como entrada nunca se enumeran en el menú de servicios en la vista de columna. Si asigna a la pestaña Nueva terminal en el servicio Carpeta un método abreviado de teclado, no funciona en la vista de columna.
- Usan la carpeta en la barra de título en lugar de requerir que primero seleccione una carpeta.
- Reutilizan la pestaña frontal si no está ocupada, por ejemplo, ejecutando un comando, mostrando una página de manual o ejecutando emacs.
Si usa 10.7 o 10.8, cambie tell application "Finder" to set p to POSIX path of (insertion location as alias)a:
tell application "Finder"
if exists Finder window 1 then
set p to POSIX path of (target of Finder window 1 as alias)
else
set p to POSIX path of (path to desktop)
end if
end tell
Hay un error en 10.7 y 10.8 (pero no en 10.9 o 10.6) donde Finder ignora las ventanas creadas después de que la última vez que el foco se movió a otra aplicación y viceversa al obtener la insertion locationpropiedad.
