Posicionando los iconos del escritorio a la izquierda en lugar de a la derecha


13

Cualquier forma de hacer automáticamente alias o íconos para que aparezcan en el lado izquierdo del escritorio de Apple. Por defecto van a la derecha.



Esta es una de las soluciones en macOS que no entiendo. ¿Por qué Apple obliga a los usuarios a tener iconos a la derecha? Puedes arrastrarlos hacia la izquierda, pero ese no es el punto. Cuando los ordenas por nombre, todo vuelve a la derecha. Incluso cuando abres Desktop En el directorio de Finder, los iconos están alineados a la izquierda! Eso es inconsistente. Tengo el idioma de mi sistema configurado para un guión de izquierda a derecha, no árabe ni hebreo ... ¿Es esta la famosa experiencia de usuario de Apple?
vtvs

Respuestas:


7

No hay forma de forzar que los íconos vayan a la izquierda automáticamente (y se mantengan ordenados según el criterio que elija).

Como solución alternativa, puede cambiar el Ver opciones en el Finder para no organizar los elementos por ningún criterio y colocar los iconos manualmente a la izquierda.

  • Haga clic en un espacio vacío en el escritorio.
  • prensa Cmd + J o usa el mouse para ir al Finder Ver & gt; Mostrar opciones de visualización menú.
  • En el Ordenar por: desplegable en el cuadro de diálogo, elija Ninguna o Encajar a la cuadricula .
  • Podrás colocar archivos en cualquier lugar de tu escritorio y se quedarán allí.

Ver Fundamentos de Mac: modifica tus ventanas para más información.

También ir a través de la Fundamentos de Mac páginas para aprender más sobre el uso de una Mac.


1
Creo que Q está preguntando sobre las opciones automáticas de Limpiar por y Ordenar por, en el menú Vista del Finder, y eso sería algo genial. ¿Por qué solo arreglar a la derecha?
Zo219

Gracias. Me perdí la parte automática y he corregido la respuesta.
M K

2

Esta no es la mejor solución, pero puede funcionar si nada más lo hace ...

  1. Cree una acción de carpeta de Automator asociada con el escritorio.
  2. Agregue el elemento: "ejecutar applecript"
  3. Pegue el siguiente código en el cuadro de texto de Applecript:

    -- https://gist.github.com/mrienstra/8330528
    -- Based on http://www.tuaw.com/2012/12/24/applescript-desktop-icon-race/
    -- Inspired by http://namesakecomic.com/comic/happy-new-year-from-namesake/#comment-1182035013
    
    -- Rearranges Desktop icons to flow from left to right, top to bottom.
    
    -- To have this run automatically every time files are added or removed from the Desktop, set this script to run as a Desktop "Folder Action". (See https://developer.apple.com/library/mac/documentation/applescript/conceptual/applescriptlangguide/reference/ASLR_folder_actions.html )
    
    -- This is currently a rough proof-of-concept. It has only been tested with OS X 10.8.5 (Mountain Lion).
    
    -- Current known limitations: Does not work with "Label position" set to "Right" (specifically, icons will overlap).
    
    
    
    -- Adjust these for different spacing
    property theSpacingFactor : 1.0
    property theGutterXFactor : 0.57
    property theGutterYFactor : 0.57
    
    
    
    on rearrangeDesktopIcons()
        tell application "Finder"
            tell icon view options of window of desktop
                set theArrangement to arrangement
                set theArrangementString to theArrangement as string
                if {"not arranged", "«constant ****narr»", "snap to grid", "«constant ****grda»"} does not contain theArrangementString then
                    display alert "\"Rearrange Desktop Icons\" AppleScript says:" message "Cannot rearrange Desktop items, please change Desktop \"Sort by\" to \"None\" or \"Snap to Grid\"." giving up after 10
                    return
                end if
                set theIconSize to icon size
                set theLabelSize to text size
            end tell
    
            set theDesktopBounds to bounds of window of desktop
            set theDesktopWidth to item 3 of theDesktopBounds
            set theDesktopHeight to item 4 of theDesktopBounds
    
            -- Retrieve a list of items on the desktop
            set theDesktopItems to every item of desktop
            set theContestantOffset to theIconSize / 2
    
            set theSpacing to (theIconSize + theLabelSize + theContestantOffset) * theSpacingFactor
            set theGuttersX to theSpacing * theGutterXFactor
            set theGuttersY to theSpacing * theGutterYFactor
            set theMaxColumns to ((theDesktopWidth - theGuttersX * 2) / theSpacing) as integer
            set theMaxRows to ((theDesktopHeight - theGuttersY * 2) / theSpacing) as integer
            set theMaxLocations to theMaxRows * theMaxColumns
    
            set y to 1
            repeat with a from 1 to length of theDesktopItems
                set x to a mod theMaxColumns
                if x is 0 then
                    set x to theMaxColumns
                end if
    
                if a is greater than theMaxLocations then
                    set desktop position of item a of theDesktopItems to {theGuttersX, theGuttersY}
                else
                    set desktop position of item a of theDesktopItems to {theGuttersX + (x - 1) * theSpacing, theGuttersY + (y - 1) * theSpacing}
                end if
    
                if a mod theMaxColumns is 0 then
                    set y to y + 1
                end if
            end repeat
        end tell
    end rearrangeDesktopIcons
    
    
    
    on adding folder items to alias after receiving listOfAlias
        rearrangeDesktopIcons()
    end adding folder items to
    
    on removing folder items from alias after losing listOfAliasOrText
        rearrangeDesktopIcons()
    end removing folder items from
    
    rearrangeDesktopIcons()
    

Por lo tanto, cada vez que se agregue un archivo a su escritorio, todos los archivos se ordenarán alfabéticamente ...


0

Organiza todas las carpetas en el orden que quieras. Luego, bajo Vista, pulsa "limpiar". Esto alineará todo muy bien. Luego, simplemente puede resaltar todas las carpetas y ubicarlas exactamente donde las desea. Las Mac no organizan carpetas a la izquierda, solo a la derecha, pero con un par de pasos fáciles puede tener todo perfectamente organizado a la izquierda.


Esto debería leer 'ver' en lugar de 'ventana' lo siento, eso fue mi error.
MikeZ

Hay un enlace de edición debajo de la respuesta que permite editar el texto directamente :-)
nohillside

0

Acabo de resaltar todas las carpetas del lado derecho, luego las agarré todas y las pegué a la izquierda.

Al usar nuestro sitio, usted reconoce que ha leído y comprende nuestra Política de Cookies y Política de Privacidad.
Licensed under cc by-sa 3.0 with attribution required.